3 méthodes de macro pour convertir rapidement vos documents Word en PDF Documents officiels

Dans cet article, nous nous concentrerons sur la fourniture de 3 macros que vous pouvez utiliser pour convertir rapidement des documents Word en pdf fichiers.

Dans Word 2003, il y a une icône dans la barre de menus. D'un simple clic, les utilisateurs peuvent déclencher instantanément la fenêtre "Enregistrer sous" et enregistrer le document dans pdf le format.

Cependant, comme vous le remarquez, la mise en page dans Word 2010 change beaucoup. Et les utilisateurs doivent cliquer sur l'onglet "Fichier" puis sur la commande "Enregistrer sous" pour déclencher la fenêtre "Enregistrer sous". De plus, vous devez choisir manuellement le type de sauvegarde avant de cliquer sur le bouton "Enregistrer".

Avec tous ces clics, ce n'est pas assez rapide. C'est pourquoi, dans cet article, nous allons vous présenter une méthode plus efficace.

Macro 1 : Déclenchez rapidement la fenêtre "Enregistrer sous"

1. Pour commencer, cliquez sur l'onglet « Développeur », puis sur la commande « Visual Basic » pour ouvrir l'éditeur VBA. Assurez-vous que l'onglet « Développeur » est déjà affiché. Vous pouvez également utiliser le raccourci clavier « Alt + F11 ».
2. Deuxièmement, cliquez sur le projet "Normal".
3. Troisièmement, cliquez sur "Insérer" puis choisissez "Module" dans le menu de la liste.
4. Maintenant, double-cliquez sur le module pour afficher la zone d'édition.
5. Ensuite, collez les codes suivants :

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Cliquez ensuite sur "Exécuter".

La fenêtre « Enregistrer sous » s'affiche. Le format PDF est déjà sélectionné. Il ne reste plus qu'à cliquer sur le bouton « Enregistrer ». Cette macro vous permet de modifier le nom du fichier si nécessaire.

Macro 2 : Enregistrer directement les fichiers Word au format PDF

Si certaines personnes souhaitent enregistrer le fichier directement dans pdf sans réviser le nom du fichier, voici la macro dont vous avez besoin.

1. Tout d'abord, répétez les 4 premières étapes ci-dessus.
2. Ensuite, collez plutôt les codes suivants :

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. De même, cliquez sur "Exécuter".

Macro 3 : Conversion par lots de fichiers Word Docx en PDF

1. Placez d'abord tous les fichiers docx dans un dossier.
2. Suivez les étapes ci-dessus pour ouvrir la zone d'édition.
3. Collez ensuite la macro ci-dessous :

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. N'oubliez jamais de cliquer sur le bouton "Exécuter".

Note: En code "strFolder = "C:\Users\Test\Desktop\Test Files\"", la ""C:\Users\Test\Desktop\Test Files\"" est le chemin de fichier du dossier. N'oubliez pas de le modifier en conséquence.

Après l'exécution de cette macro, les fichiers PDF seront enregistrés dans le même dossier que les documents Word.

Sécurisez les fichiers comme vous le pouvez

Il existe des mesures préventives et des actions post-catastrophe pour récupérer les fichiers endommagés. Si vous sauvegardez régulièrement vos fichiers, restaurer le fichier original est un jeu d'enfant. Malheureusement, peu de personnes respectent leur plan de sauvegarde, ce qui augmente le risque de perdre des données précieuses. Dans ce cas, il est temps de recourir à une solution plus avancée. Outil de correction de corruption de document Word.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris correctif Excel xlsx endommagé et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com