3 façons rapides de supprimer des lignes et des colonnes vides dans votre tableau Word

Dans cet article, nous vous expliquerons 3 façons rapides de supprimer les lignes et les colonnes vides de votre tableau Word.

Les tableaux sont essentiels à un document, en particulier pour contenir divers types de données. Parfois, un long tableau peut dépasser une page et s'étendre sur plusieurs. Donc, une fois qu'un tableau devient long et compliqué, il existe des mesures que vous pouvez prendre pour le simplifier. Par exemple, vous pouvez supprimer les lignes et les colonnes vides inutiles.

Voici 3 méthodes que vous pouvez utiliser.

Méthode 1 : Supprimer manuellement les lignes et les colonnes vides

1. Tout d'abord, sélectionnez une ligne ou une colonne en blanc.
2. Puis faites un clic droit pour obtenir le menu contextuel. Dans le menu, sélectionnez "Supprimer les lignes" ou "Supprimer les colonnes" en conséquence.

Malheureusement, vous ne pouvez pas sélectionner plusieurs lignes ou colonnes non consécutives et les supprimer ensemble de cette façon. Pour cette demande, vous pouvez vous référer à notre article précédent : 5 méthodes rapides pour supprimer par lots plusieurs lignes ou colonnes dans votre tableau Word

Méthode 2 : suppression par lots de toutes les lignes et colonnes vides d'un tableau

La méthode 1 a ses limites. Nous allons donc vous proposer le moyen de supprimer par lots des lignes et des colonnes dans un tableau via des codes VBA.

1. Pour commencer, placez le curseur à l'intérieur d'un tableau cible.
2. Deuxièmement, lancez l'éditeur VBA en appuyant sur "Alt + F11".
3. Dans l'éditeur, cliquez d'abord sur le projet "Normal".
4. Cliquez ensuite sur l'onglet "Insérer" dans la barre de menu.
5. Dans le menu déroulant, choisissez "Module".
6. Double-cliquez sur le module pour l'ouvrir et collez-y les codes suivants :

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Enfin, cliquez sur le bouton "Exécuter" dans la barre de menu ou appuyez sur "F5".

En quelques secondes, toutes les lignes et colonnes vides de ce tableau seront supprimées.

Méthode 3 : suppression par lots de toutes les lignes et colonnes vides dans tous les tableaux d'un document

1. Tout d'abord, répétez les étapes de la méthode 2 pour installer et exécuter une macro.
2. Seulement cette fois, remplacez cette macro par ce qui suit :

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Récupérer un document cassé

Il existe aujourd'hui plusieurs façons de récupérer des données perdues. Par exemple, la restauration des sauvegardes reste la priorité absolue. Si cela ne suffit pas à récupérer vos informations les plus récentes, vous pouvez alors essayer… doc réparation outil.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation xlsx et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com