2 méthodes pour envoyer rapidement des cellules sélectionnées dans une feuille de calcul Excel en tant qu'e-mail Outlook

Parfois, vous souhaiterez peut-être insérer rapidement les cellules sélectionnées dans une feuille de calcul Excel dans un e-mail Outlook et envoyer cet e-mail. Cet article se penchera sur ce souhait pour vous proposer 2 méthodes.

Mon article précédent "2 méthodes rapides pour envoyer une feuille de calcul Excel en tant qu'e-mail Outlook” vous a appris à envoyer une feuille de calcul Excel entière par e-mail. Cependant, parfois, vous souhaitez uniquement envoyer les cellules sélectionnées dans une feuille de calcul par e-mail. En réponse à cette exigence, nous allons ici vous exposer 2 méthodes. Vous pouvez choisir l'un ou l'autre selon vos préférences.

Méthode 1 : copier manuellement les cellules sélectionnées dans un e-mail

1. À start avec, ouvrez le fichier Excel source et accédez à la bonne feuille de calcul Excel.
2. Sélectionnez ensuite les cellules que vous souhaitez envoyer en tant qu'e-mail Outlook.
3. Appuyez ensuite sur les raccourcis clavier "Ctrl + C" pour copier les cellules sélectionnées.
4. Après cela, lancez votre application Outlook.
5. Ensuite, cliquez sur le bouton "Nouvel e-mail" dans le ruban "Accueil" pour créer un nouvel e-mail Outlook.
6. Plus tard dans la nouvelle fenêtre de message, cliquez dans la section du corps du message.
7. Et puis appuyez sur les touches "Ctrl + V" pour coller les cellules Excel sélectionnées précédemment copiées.
8. Enfin, vous pouvez rédiger l'e-mail comme d'habitude et cliquer sur le bouton "Envoyer" pour l'envoyer.

Méthode 2 : Envoyer les cellules sélectionnées par e-mail via VBA

1. Au tout début, ouvrez le classeur Excel source.
2. Appuyez ensuite sur les touches "Alt + F11" pour accéder à l'éditeur Excel VBA.
3. Dans la nouvelle fenêtre, cliquez sur "Insérer" > "Module" pour insérer un nouveau module.
4. Ensuite, vous devez activer l'objet Microsoft Outlook. Cliquez sur "Outils" > "Références". Dans la boîte de dialogue contextuelle, recherchez et cochez la "Microsoft Outlook Object Library ».
5. Ensuite, copiez le code VBA suivant dans ce module.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Finalement, vous pouvez essayer.

• Tout d'abord, sélectionnez les cellules spécifiques comme d'habitude.
• Revenez ensuite à la nouvelle macro et appuyez sur la touche F5 pour la déclencher.
• Immédiatement, un nouvel e-mail Outlook s'affiche, dans lequel vous pouvez voir que les cellules sélectionnées ont été insérées dans le corps de l'e-mail, comme la capture d'écran suivante :

Le fichier PST est le même vulnérable que le fichier Excel

Comme nous le savons, les fichiers Excel et les documents Word sont sujets à la corruption. En fait, il en va de même pour le fichier PST, qui contient tous les éléments de votre boîte aux lettres Outlook. C'est donc une tâche ardue de sécuriser vos données PST. L'un d'euxost des mesures efficaces consiste à sauvegarder régulièrement le fichier. De plus, afin de fournir un secours immédiat, vous feriez mieux de préparer un outil expérimenté, tel que DataNumen Outlook Repair, qui est capable de récupérer Outlook données sans suer.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com