2 façons rapides d'extraire des sections de votre document Word

Dans cet article, nous allons vous proposer 2 façons simples et rapides d'extraire des sections de votre document Word vers un ou plusieurs autres.

Il arrive assez souvent d'extraire le contenu d'un document à un autre. Et dans notre article précédent, nous avons expliqué comment extraire des pages d'un document. Pour des informations détaillées, vous pouvez vous référer à cet article : 2 façons rapides d'extraire des pages individuelles de votre document Word

Aujourd'hui, nous allons vous montrer comment extraire par section.    

Méthode 1 : Extraire la section actuelle dans un nouveau document

1. Tout d'abord, positionnez le curseur dans une section cible.
2. Appuyez ensuite sur "Alt + F11" pour appeler l'éditeur VBA dans Word.
3. Puis dans la colonne de gauche, cliquez sur "Normal".
4. Et dans la barre de menu, cliquez sur "Insérer".
5. Choisissez ensuite "Module" dans ce menu déroulant.
6. Double-cliquez pour ouvrir le nouveau module et collez-y les codes suivants :

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Ensuite, cliquez sur "Exécuter" dans la barre de menu ou appuyez sur "F5".
8. Ensuite, la fenêtre "Parcourir" apparaîtra. Choisissez un emplacement pour stocker le nouveau document et cliquez sur "OK".
9. Et dans la case "Nom de fichier", entrez le nom du nouveau fichier et cliquez sur "OK".

Vous avez maintenant extrait la section dans un nouveau document.

Méthode 2 : Extrayez chaque section du document vers de nouvelles sections individuelles

De cette façon, vous pouvez traiter par lots toutes les sections d'un document. Bien sûr, nous aurons également besoin d'une macro.

1. Pour commencer, ouvrez le document cible.
2. Suivez ensuite les étapes de la méthode 1 pour installer et exécuter une macro.
3. Seulement cette fois, remplacez cette macro par celle-ci :

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Toujours dans la fenêtre "Parcourir", choisissez un chemin de stockage et cliquez sur "OK".

Corriger les erreurs de mot irritantes

Il est courant de rencontrer des erreurs Word lors de son utilisation. Ennuyeux que cela puisse être, il faut prendre le temps de récupérer le mot dès que possible. Parce que plus nous le retardons, plus la perte de données peut être grave. Par conséquent, il est suggéré de se procurer un utilitaire de réparation à l'avance.

Introduction de l'auteur:

Vera Chen est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris xl corrompu et pdf réparer les produits logiciels. Pour plus d'informations, visitez www.datanumen.com