Kuinka viedä kaikki Outlook-sähköpostin liitetiedostot nopeasti Excel-laskentataulukkoon

Jos haluat viedä kaikki Outlook-sähköpostin liitetiedostot nopeasti Excel-laskentataulukkoon, voit viitata tähän artikkeliin. Tässä näytämme sinulle tehokkaamman tavan kuin manuaalinen vienti.

Kun saat sähköpostiviestin, joka sisältää useita kuvaliitteitä, ja haluat käyttää niitä Excel-raportin tekemiseen, sinun on löydettävä tapa viedä nämä kuvat Excel-laskentataulukkoon erissä. Seuraavaksi esittelemme sinulle tällaisen lähestymistavan.

Vie kaikki sähköpostin liitetiedostot Excel-laskentataulukkoon

1. Ensinnäkin, käytä Outlook-sovellusta normaalilla tavalla.
2. Paina sitten Outlook-ikkunassa Alt + F11-pikanäppäimiä, jolloin esiin tulee "Microsoft Visual Basic for Applications" -ikkuna.
3. Tässä näytössä sinun on avattava moduuli, jota ei käytetä, tai lisätä uusi suoraan.
4. Seuraavaksi sinun on kopioitava alla oleva VBA-koodikappale tähän moduuliin.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Tämän jälkeen voit poistua makrosta.
6. Siirry sitten kohtaan "File"> "Options"> "Quick Access Toolbar" lisätäksesi tämän makron Quick Access Toolbariin.
7. Lopuksi voit kokeilla tätä makroa juuri nyt.

• Ensinnäkin, valitse tai avaa lähdesähköposti.
• Napsauta sitten pikakäynnistystyökalurivin makropainiketta.
• Kun makro on valmis, saat Excel-laskentataulukon, joka näkyy kuten seuraava kuvakaappaus:

Suojaa Outlook-tiedosto vioittumiselta

Tiedetään, että Outlook on altis korruptiolle. Siksi meidän pitäisi ymmärtää, miten suojata Outlook-lomakkeiden vioittuminen. Ensinnäkin virushyökkäysten estämiseksi on välttämätöntä asentaa virustorjuntaohjelma eikä koskaan ladata tuntematonta liitettä. Lisäksi meillä on parempi saada käsiinsä tehokas korjaustyökalu, kuten DataNumen Outlook RepairSe voi tarjota tehokkaimman ratkaisun, jos Outlookin korruptio.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql-palautus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com