Kuinka kopioida nopeasti kansiorakenne yhdestä Outlookin PST-tiedostosta toiseen VBA:n kautta

Jos haluat kopioida kansiorakenteen yhdestä Outlook PST -tiedostosta toiseen, voit käyttää tässä artikkelissa esiteltyä menetelmää, joka opettaa sinulle, kuinka VBA:n avulla saat sen yhdellä kertaa.

Ehkä, jotta voit hallita sähköpostejasi paremmin, olet luonut useita mukautettuja kansioita Outlookin päätiedostoon. Kun luot uuden Outlookin PST-tiedoston, saatat haluta käyttää samaa kansiorakennetta. Itse asiassa edellisessä artikkelissani - "2 vaihetta nykyisen kansiohierarkian säilyttämiseksi uudessa Outlook-tiedostossa”, voit oppia perinteisen menetelmän, joka käyttää "Arkisto"-ominaisuutta saavuttaakseen sen. Siitä huolimatta se on itse asiassa edelleen hieman tylsää. Siihen verrattuna VBA-koodien käyttö sen saamiseen on paljon nopeampaa. Siksi seuraavassa kerromme sinulle yksityiskohtaiset vaiheet ja koodit.

Kopioi kansiorakenne yhdestä Outlookin PST-tiedostosta toiseen

1. Käynnistä Outlook-ohjelmasi aivan aluksi.
2. Paina sitten Outlook-ikkunassa Alt + F11-näppäinpainikkeita.
3. Seuraavaksi siirryt Outlook VBA -editori-ikkunaan.
4. Kopioi ja liitä sitten seuraavat VBA-koodit uuteen moduuliin.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Muuta sen jälkeen makron suojaustasosi alhaiseksi.
6. Palaa myöhemmin VBA-editori-ikkunaan ja paina “F5”-näppäintä suorittaaksesi makron.
7. Lopuksi, kun makro on toiminut, saat viestin, jossa kehotetaan "Valmis!".
8. Tässä vaiheessa voit siirtyä sähköpostin navigointiruutuun. Näet uuden Outlook-datatiedoston, joka on samassa kansiorakenteessa kuin lähde-PST-tiedosto, kuten alla oleva kuva:

Selviydy masentavista PST-ongelmista

Koska Outlook PST on virhealtis, monet teistä ovat joskus kohdanneet erilaisia ​​Outlookin ongelmia. Kun kohtaat ne, voit ensin kokeilla Outlook-postilaatikon korjaustyökalua. Jos se epäonnistuu, voit käyttää tehokkaampaa kolmannen osapuolen työkalua, kuten DataNumen Outlook Repair, joka voi korjaa Outlook PST-virheet kuin tuulta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien SQL Server korjata ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com