Word-asiakirjan tiettyjen sivujen nopea liittäminen Outlook-sähköpostiin

MS Word sisältää suoran ominaisuuden, joka tukee käyttäjiä lähettämään nykyisen Word-asiakirjan sähköpostin liitteenä. Mutta joskus saatat vain toivoa liittävän Word-asiakirjan tietyt sivut Outlook-sähköpostiin. Nyt tämä artikkeli jakaa sinulle menetelmän.

Voit lähettää koko Word-asiakirjan sähköpostiliitteenä MS Word -sovelluksessa siirtymällä Tiedosto-valikkoon ja siirtymällä Tallenna ja Lähetä -välilehdelle, josta löydät Lähetä liitetiedostona -painikkeen. Toisinaan lähetettävät tiedot voivat kuitenkin olla vain asiakirjan tiettyjä sivuja. Tässä tilanteessa voit käyttää sen toteuttamiseen seuraavissa esiteltyä menetelmää.

Liitä Word-asiakirjan tietyt sivut sähköpostiin

1. Ensinnäkin, avaa Word-lähdeasiakirja, jonka sivut haluat lähettää sähköpostitse.
2. Kun olet päässyt MS Word -ikkunaan, sinun on painettava "Alt + F11" -näppäimiä.
3. Seuraavaksi saat pääsyn VBA-editoriin MS Wordissa.
4. Sen jälkeen sinun on otettava käyttöön ”Microsoft Outlook Object Library”. Voit tehdä sen valitsemalla ”Työkalut” > ”Viite”.
5. Sen jälkeen sinun on kopioitava seuraava VBA-koodi moduuliin, jota ei käytetä.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Lopuksi voit suorittaa tämän makron. Paina vain F5-näppäintä tai napauta työkalupalkin Suorita-kuvaketta.
7. Kun makro on valmis, näyttöön tulee uusi Outlook-sähköposti, joka on liitetty otteeseen lähdetekstistä Word, kuten seuraava kuvakaappaus:

Pura enimmäistiedot vioittuneesta Outlook-tiedostosta

Jos olet käyttänyt Outlookia vuosikymmenien ajan, saatat joutua kohtaamaan erilaisia ​​Outlook-ongelmia, kuten ponnahdusikkunoiden sisäiset virheilmoitukset, äkilliset kaatumiset ja vakavat tiedostovauriot. Johtuen siitä, että scanpst, sisäänrakennettu korjaustyökalu, pystyy käsittelemään vain pieniä ongelmia, sinun on parasta pitää ulkoinen tehokas korjaustyökalu kätevänä, sanokaa DataNumen Outlook Repair. Se pystyy saamaan enimmäistiedot vahingoittuneesta Outlook-datatiedostosta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien sql-korjaus ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com