Kuinka viimeksi muokattu tiedosto voidaan nopeasti liittää Windows-kansioon Outlook-sähköpostiisi

Toisinaan kannattaa ehkä löytää ja liittää nopeasti viimeinen muokattu tiedosto tietyssä Windows-kansiossa Outlook-sähköpostiin. Tässä tapauksessa voit käyttää tässä artikkelissa esitettyä menetelmää.

Jotkut käyttäjät haluavat antaa Outlookin nopeasti selvittää ja liittää sähköpostiin Windows-kansion viimeksi muokatun tiedoston, kuten viimeksi luodun, muutetun tai tallennetun tiedoston. Outlook ei kuitenkaan tarjoa tällaista suoraa ja natiivia ominaisuutta. Siksi seuraavassa esittelemme VBA-koodinpätkän, joka mahdollistaa tämän helposti.

Liitä viimeksi muokattu tiedosto Windows-kansioon sähköpostiin

1. Alusta alkaen sinun on käynnistettävä Outlook-sovellus.
2. Kun olet päässyt Outlookin pääikkunaan, voit painaa ”Alt + F11” -näppäimiä.
3. Seuraavaksi pääset Outlook VBA -editori -ikkunaan onnistuneesti.
4. Tämän jälkeen sinun pitäisi löytää ja avata moduuli, jota ei käytetä.
5. Kopioi ja liitä sitten seuraava VBA-koodi tähän moduuliikkunaan.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Tämän jälkeen voit poistua nykyisestä VBA-editori-ikkunasta ja jatkaa uuden makron lisäämistä Pikakäynnistystyökaluriville tai Viesti-ikkunan nauhalle.
7. Myöhemmin sinun on muutettava Outlookin makrotason suojaustaso matalaksi.
8. Lopulta voit kokeilla.

• Luo ja kirjoita ensin uusi Outlook-sähköposti tavalliseen tapaan.
• Napsauta sitten pikakäynnistystyökalurivin makropainiketta, kuten alla oleva kuva:
• Seuraavaksi sinun on valittava lähdekansio Windows ja painettava “OK”.
• Jos valitussa Windows-kansiossa on tällainen tiedosto, saat kehotteen, kuten seuraava kuvakaappaus:
• Kun painat “Kyllä”, tämä tiedosto liitetään kerralla.

Ratkaise Outlook-ongelmat mahdollisimman pian

Aina kun kohtaat Outlook-ongelmia, on suositeltavaa ratkaista ne mahdollisimman pian. Tässä tilanteessa sinun on parasta valmistaa vankka Outlook-korjaus työkalu etukäteen, kuten DataNumen Outlook Repair. Se pystyy korjaamaan PST-virheet ja pelastamaan Outlook-tiedot tehokkaasti.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vioittunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com