Kuinka nopeasti purkaa kaikki vastaanottajat useista Outlook-viestitiedostoista (.msg)

Jotkut käyttäjät haluavat purkaa kaikki vastaanottajat nopeasti useista Outlook-sähköpostitiedostoista, jotka on tallennettu Outlook-sähköposteista. Nyt tämä sost tarkastelee tätä jakaa nopea lähestymistapa.

Voit purkaa vastaanottajat yhdestä Outlook-viestitiedostosta avaamalla sen kaksoisnapsauttamalla sitä ja kopioimalla vastaanottajat sitten avattuun viesti-ikkunaan. Mutta jos sinun on käsiteltävä erä Outlook-viestitiedostoja, manuaalinen menetelmä ei ole tarpeeksi tehokas. Voit siis etsiä paljon tehokkaampaa tapaa. Täällä esittelemme sellaisen sinulle. Lue sen yksityiskohdat.

Pura kaikki vastaanottajat useista Outlook-viestitiedostoista (.msg)

1. Sillä kutentart, pääset käyttämään Outlook VBA -editoria “Kuinka suorittaa VBA-koodi Outlookissa".
2. Kopioi ja liitä seuraava VBA-koodi tyhjään moduuliin.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Siirrä sitten kohdistinta ensimmäiseen aliohjelmaan.
4. Napsauta sitten ”Suorita” -painiketta tai paina “F5” -näppäintä.
5. Valitse sitten ponnahdusvalikosta Windows-kansio, joka sisältää lähde-Outlook-viestitiedostot (.msg).
6. Kun olet valinnut, napsauta “OK”, jotta makro jatkuu.
7. Kun makro on valmis, näkyviin tulee viesti, jossa luetellaan kaikki puretut vastaanottajien sähköpostiosoitteet, kuten seuraava kuvakaappaus osoittaa.

Suojaa Outlook-tietosi Jeopardylta

Outlook-tiedot ovat todennäköisesti alttiita korruptiolle. Näin ollen Outlook-tietojen suojaaminen on melko raskas tehtävä. Se vaatii sinua jatkamaan säännöllistä varmuuskopiointia Outlook-tiedoille. Lisäksi, jos mahdollista, on järkevää ja suositeltavaa laatia kokenut ja ammattitaitoinen Outlook PST-korjaus työkalu, kuten DataNumen Outlook Repair, jotta voit saada välitön ja oikea-aikainen pelastus Outlookin vioittumisen yhteydessä.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien toipua Sql Server ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com