2 tapaa viedä kaikki Outlook-yhteysryhmän jäsenet Exceliin

Joskus haluat ehkä viedä jäsenet tiettyyn Outlook-yhteysryhmään. Joten tämä artikkeli jakaa sinulle 2 keinoa poimia ryhmän jäsenet Exceliin.

Outlook tarjoaa natiivitoiminnon, jonka avulla voit viedä kaikki tietyn yhteystietokansion yhteystiedot. Se ei kuitenkaan salli sinun viedä yhteysryhmiä, puhumattakaan jäsenryhmien purkamisesta. Siksi, jos haluat purkaa valitun yhteysryhmän jäsenet, sinun on tehtävä vielä enemmän. Tässä on kaksi vinkkiä, joihin voit viitata.

Tapa 1: Pura ryhmän jäsenet Tallenna nimellä

1. Käynnistä Outlook heti alussa.
2. Etsi ja valitse sitten yhteysryhmä, jonka jäsenet sinun on purettava.
3. Seuraavaksi sinun pitäisi mennä "Tiedosto" -valikkoon ja napsauttaa "Tallenna nimellä".
4. Valitse seuraavaksi ponnahdusikkunassa Tallenna nimellä -valintaikkunassa kohdekansio, jonka haluat tallentaa, ja valitse "Vain teksti" avattavasta "Tallenna nimellä" -luettelosta.
5. Napsauta sitten "Tallenna".
6. Tämän jälkeen avaa Excel ja luo uusi Excel-tiedosto.
7. Myöhemmin sinun tulisi kääntyä kohtaan "Tiedosto" ja napsauttaa "Avaa" -painiketta.
8. Seuraavassa "Avaa" -valintaikkunassa sinun on ensin käytettävä kansiota, johon tallensit yhteysryhmän juuri nyt.
9. Napsauta sitten "File name" -rivin toista ruutua ja valitse avattavasta luettelosta "All Files".
10. Tämän jälkeen kohota yhteystietoryhmän tekstitiedosto ja paina "Avaa".
11. Varmista ponnahdusikkunassa Ohjattu tekstin tuonti -valintaikkunassa, että ”Rajoitettu” on valittuna, ja napsauta ”Valmis” -painiketta.
12. Lopuksi saat jäsenet, kuten seuraava kuvakaappaus:

Tapa 2: Pura ryhmän jäsenet Outlook VBA: n kautta

1. Ensinnäkin, paina "Alt + F11" -näppäimiä Outlookissa.
2. Avaa sitten uusi moduuli VBA-editori-ikkunassa.
3. Kopioi sitten seuraavat VBA-koodit siihen.

Sub ExtractContactGroupMembersToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objMember As Outlook.recipient
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strPath As String
    Dim strFilename As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objContactGroup = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objContactGroup = Application.ActiveInspector.CurrentItem
    End Select
 
    If TypeOf objContactGroup Is DistListItem Then
       'Create a new Excel workbook
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkBook = objExcelApp.Workbooks.Add
       Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
       'Set the two column headers
       objExcelWorkSheet.Cells(1, 1) = "Contact Name"
       objExcelWorkSheet.Cells(1, 2) = "Email Address"

       nRow = 2
 
       'Extract the contact group members' names and email addresses
       For i = 1 To objContactGroup.MemberCount
           Set objMember = objContactGroup.GetMember(i)
           objExcelWorkSheet.Cells(nRow, 1) = objMember.Name
           objExcelWorkSheet.Cells(nRow, 2) = objMember.Address
           nRow = nRow + 1
       Next
 
       'AutoFit the columns in the new Excel worksheet
       objExcelWorkSheet.Columns("A:B").AutoFit
 
       'Change the strPath to your actual case
       strPath = "C:\Contact Groups\"
       strFilename = strPath & objContactGroup.DLName & ".xlsx"
 
       'Save the Excel workbook
       objExcelWorkBook.Close True, strFilename
 
       'Notify you of the export complete
       MsgBox ("Export Complete!")
    End If
End Sub

4. Sen jälkeen voit lisätä makron Quick Access Toolbariin (QAT) tavalliseen tapaan.
5. Myöhemmin voit valita yhteysryhmän ja napsauttaa makropainiketta QAT: ssa.
6. Viemisen jälkeen saat viestin - "Vienti valmis!"
7. Lopulta löydät Excel-tiedoston kansiosta, joka on ennalta määritetty VBA-koodeissa. Avaa se, niin näet ryhmän jäsenet, kuten alla olevan kuvan:

Palaa edellisiin PST-tietoihin

Koska Outlook on altis kaatumiselle, PST-tietosi voivat vioittua ilman mitään merkkejä. Siksi sinun tulisi tehdä säännöllinen varmuuskopio PST-tiedostoistasi. Sinun on myös parempi valmistaa voimakas työkalu, kuten DataNumen Outlook Repair, joka voi korjata Outlook tietoja ajoissa.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjaa sql ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com