Kuinka erät lähettää kaikki laskentataulukot yhdessä Excel-työkirjassa erillisinä Outlook-sähköposteina

Jos haluat lähettää kaikki Excel-työkirjan laskentataulukot erillisinä Outlook-sähköposteina, voit käyttää tässä artikkelissa esitettyä menetelmää. Se voi opastaa sinua ymmärtämään sen irtotavarana lähettämättä ongelmitta yksitellen.

Edellisessä viestissäni "2 nopeaa tapaa lähettää Excel-laskentataulukko Outlook-sähköpostina”, voit oppia kaksi tapaa lähettää yksi Excel-laskentataulukko sähköpostitse. Jos haluat lähettää kaikki yhden työkirjan laskentataulukot erillisinä sähköposteina, jommankumman kyseisessä viestissä mainitun tavan käyttäminen on melko työlästä ja hankalaa. Siksi esittelemme tässä toisen tavan, jolla tällainen ”erälähetys” voidaan toteuttaa nopeasti.

Erä Lähetä kaikki laskentataulukot yhdessä Excel-työkirjassa erillisinä sähköposteina

1. Ensinnäkin, sinun pitäisi avata lähde Excel-työkirja.
2. Sitten, kun olet saapunut Excel-ikkunaan, sinun pitäisi napauttaa "Alt + F11" -näppäimen pikanäppäimiä.
3. Seuraavaksi tulee näkyviin toinen ikkuna nimeltä Microsoft Visual Basic for Applications.
4. Siinä sinun on avattava käyttämätön moduuli tai lisättävä uusi moduuli.
5. Tämän jälkeen voit kopioida seuraavan VBA-koodin tähän moduuliin.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Sen jälkeen voit käynnistää tämän makron painamalla F5-näppäinpainiketta tai napsauttamalla työkalupalkin Suorita-kuvaketta.
7. Sähköpostit, jotka vastaavat kaikkia tämän Excel-työkirjan laskentataulukoita, näkyvät kerralla Outlookissa.
8. Lopuksi voit tarkistaa kaikki sähköpostiviestien tiedot ja lähettää viimeiseksi napsauttamalla Lähetä-painiketta.

Käytä tehokasta palautustyökalua, jos varmuuskopioita ei ole

Yhä useammat käyttäjät ovat ymmärtäneet varmuuskopioiden merkityksen. Niin kauan kuin olet varmuuskopioinut PST-tiedostosi, PST-palautus vaurioiden jälkeen on melko yksinkertainen. Mutta jos ei ole tehokasta ja ajan tasalla olevaa PST-varmuuskopiota, sinulla ei ole muuta vaihtoehtoa kuin ottaa apua ulkoisesta PST-korjaustyökalusta, kuten DataNumen Outlook Repair. Se voi korjata vaarantuneita PST-tiedostoja kuin tuulta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien palauttaa sql ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com