Hyperlinkkien poistaminen käytöstä tuntemattomilta lähettäjiltä tulevissa Outlook-sähköpostiviesteissä

Haitallisten linkkien estämiseksi sinun on parasta määrittää Outlook poistamaan hyperlinkit käytöstä tuntemattomilta lähettäjiltä tulevissa sähköposteissa. Tämä artikkeli paljastaa osan VBA-koodeista, jotka voivat auttaa sinua saamaan sen kuin korkki.

Monet käyttäjät ovat valittaneet, että sähköpostitse välitetyt virukset hyökkäsivät heidän Outlook-tiedostoonsa. Useimmiten se johtuu siitä, että he luottavat helposti tuntemattomien lähettäjien lähettämiin sähköposteihin. Joten he lataavat tai napsauttavat sähköpostiviestien hyperlinkkejä. Nyt, jäljempänä, jaamme menetelmän. Se voi antaa Outlookin poistaa käytöstä tuntemattomilta lähettäjiltä saapuvien sähköpostien hyperlinkit. Jos sinulla on tällaisia ​​tarpeita, lue lisää saadaksesi lisätietoja.

Poista hyperlinkit käytöstä automaattisesti tuntemattomilta lähettäjiltä tulevissa sähköposteissa

1. Sillä kutentart, siirry Outlookissa VBA-editoriin valitsemalla ”Alt + F11”.
2. Lisää seuraavaksi uudessa näytössä "MS VBScript Regular Expressions" -objekti sivun mukaisestiost "Objektin lisääminen Library Viite VBA: ssa".
3. Kopioi ja liitä sitten seuraava koodi ThisOutlookSession-projektiin.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Tämän jälkeen aktivoi tämä makro joko restart Outlook tai ”F5” -näppäimen painaminen kohdassa ”Application_Startup ”-alirutiini.
5. Siitä lähtien, aina kun lähettäjältä tuleva sähköposti, jota ei ole tallennettu oletusyhteystietokansioon, pääsee Saapuneet-kansioon, Outlook poistaa automaattisesti siinä olevat hyperlinkit.

Useat välttämättömyysasiat Outlook-suojauksessa

Koska Outlook on altis vahingoille, Outlook-tiedostoa on melko vaikea suojata. Tässä luetellaan useita pakollisia omaisuuksia Outlook-tietosuojan aikana. Ensinnäkin sinun on varmuuskopioitava Outlook-tiedot säännöllisesti. Lisäksi sinun on varottava kaikista mahdollisista riskeistä, kuten haitallisista liitteistä tai hyperlinkeistä. Viimeisenä mutta ei vähäisimpänä, sinun on valmisteltava tehokas Outlook-korjaustyökalu etukäteen, kuten DataNumen Outlook Repair. Se tulee varmasti käteväksi, kun tarvitset korjaa PST tiedosto, mutta Saapuneet-kansion korjaustyökalu osoittaa epäonnistumisen.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien vaurioitunut mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com