Sähköpostin luokkien automaattinen soveltaminen kaikkiin vastauksiin ja edelleenlähetyksiin Outlookissa

Kun vastaat tai välität sähköpostia, haluat ehkä soveltaa samoja luokkia. Tässä artikkelissa opetamme sinut ymmärtämään tämän VBA-koodilla.

Jos olet tottunut osoittamaan samat alkuperäisen sähköpostin väriluokat kaikille vastauksille ja edelleenlähetyksille, miksi et anna Outlookin saavuttaa tätä automaattisesti? Vaikka Outlook ei tarjoa niin suoraa ominaisuutta, voit silti saada sen VBA-koodin avulla. Seuraavassa paljastamme sinulle yksityiskohtaiset vaiheet ja koodin.

Käytä sähköpostin luokkia automaattisesti kaikkiin vastauksiin ja edelleenlähetyksiin

1. Käynnistä Outlook-sovellus heti alusta.
2. Suorita sitten Outlook VBA -editori painamalla Alt + F11-näppäimiä.
3. Kopioi seuraavaksi seuraava VBA-koodi “ThisOutlookSession” -projektiin.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Käynnistä sen jälkeen Outlook uudelleen aktivoidaksesi tämän projektin.
5. Sittemmin voit kokeilla sitä seuraamalla alla olevia ohjeita.

• Ensinnäkin, valitse sähköposti ja paina "Lähetä" -painiketta.
• Sitten näyttöön tulee edelleenlähetyssähköposti, jossa voit siirtyä Asetukset-välilehdelle ja painaa laajennuskuvaketta Lisää vaihtoehtoja -ryhmän oikeassa alakulmassa.
• Seuraavaksi ponnahdusikkunassa "Ominaisuudet" -valintaikkunassa näet, että tämä sähköposti on määritetty samoilla väriluokilla kuin alkuperäinen sähköposti.

Korjaa vioittunut Outlook-tiedosto

Kun otetaan huomioon, että Outlook on haavoittuva, sinun on tehtävä paljon toimia Outlookin tietojen häviämisen välttämiseksi. Esimerkiksi sinun on tehtävä säännöllisiä varmuuskopioita. Lisäksi sinun on varottava tuntemattomia sähköposteja, mukaan lukien upotetut linkit tai liitteet. Viimeisenä mutta ei vähäisimpänä, sinun pitäisi saada käsiinsä tip-top-ulkoinen korjaustyökalu, kuten DataNumen Outlook Repair. Se voi auttaa sinua saamaan enimmäistiedot korruptoitunut Outlook tiedosto.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien SQL Server korjata ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com