Kolme tapaa saada asiakirjan tekstiruutuihin, alaviitteisiin ja loppuviitteisiin liittyviä sanamäärätilastoja

Tämänpäiväisessä artikkelissa on 3 nopeaa tapaa saada tekstiruutuihin, alaviitteisiin ja loppuviitteisiin liittyviä sanamäärätilastoja asiakirjaan.

Dokumentin sanojen kokonaismäärän saaminen ei ole vaikeaa. Mutta jos haluat saada sanamäärän erityyppisiä tekstejä, tarvitaan lisää toimintoja. Seuraavassa on 3 menetelmää. Lue lisää siitä, mitä voit käyttää. 

Tapa 1: Laske sanat, jotka sisältävät tekstiruutujen, alaviitteiden ja loppuviitteiden tekstejä

Oletuksena Word laskee kaikki asiakirjassa esiintyvät sanat, mukaan lukien tekstiruutujen tekstit sekä alaviitteistä ja loppuviitteistä tulevat sanat.

1. Ensinnäkin, siirry tilariville ja napsauta "Sanat" avataksesi "Sanamäärä"-ruudun.
2. Siellä näet kaikenlaisia ​​tilastoja. Varmista, että olet valinnut Sisällytä tekstilaatikot, alaviitteet ja loppuviitteet -valintaruudun.
3. Napsauta sitten "Sulje".
4. Jos et löydä “Sanat” -komentoa tilariviltä, ​​napsauta sitä hiiren kakkospainikkeella.
5. Seuraavaksi tarkista "Sanamäärä".

Tapa 2: Sulje pois tekstikentät tekstiruuduista, alaviitteistä ja loppuviitteistä sanamäärästä

Tämä on päinvastoin kuin menetelmä 1. Joten sinun tarvitsee vain poistaa valinta Lisää tekstiruutuja, alaviitteitä ja loppuviitteitä -valintaruudusta.

Tapa 3: Suorita Word-makro saadaksesi erillisen sanamäärän laatikoista, alaviitteistä ja loppuviitteistä

1. Ensinnäkin, laukaise "Sanamäärä" -ruutu tapaan menetelmässä 1 ja varmista, että valintaruutu on valittu.
2. Avaa seuraavaksi VBA-editori painamalla Alt + F11.
3. Lisää sitten uusi moduuli “Normal” -projektiin napsauttamalla ensin “Normal”.
4. Napsauta sitten Lisää.
5. Valitse sitten ”Moduuli”.
6. Kaksoisnapsauta moduulia avataksesi koodausalueen ja liittämällä seuraavat koodit sinne:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Napsauta lopuksi Suorita-painiketta.

Jos tekstiruutua, alaviitettä tai loppuviitettä ei ole, saat viestiruudun seuraavasti:

Napsauta vain "OK" jatkaaksesi. Sitten näet toisen laatikon, jossa luetellaan kaikki sanamäärän yksityiskohdat.

Hanki palautustyökalu

Koska Word voi romahtaa yhtäkkiä, on suositeltavaa hankkia edistyksellinen korjaustuote korjaustöiden tekemistä varten. Tällainen työkalu voi olla hyvä säästäjä korruptoitunut Word. Siksi tartu aikaasi saadaksesi yksi mahdollisimman pian.

Tekijän esittely:

Vera Chen on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjaa xls ja pdf korjata ohjelmistotuotteita. Lisätietoja osoitteessa www.datanumen.com