2 tapaa tulostaa luettelot Outlook-tehtävistä, joilla on eri luokat eri sivuilla

Jos olet määrittänyt useita väriluokkia Outlook-tehtäviisi ja haluat nyt tulostaa luettelot tehtävistä, joilla on eri luokat eri sivuilla, voit viitata tähän artikkeliin. Täällä jaamme sinulle 2 tapaa saada se.

Voit luokitella ja hallita tehtäviäsi kenties olet soveltanut tehtävällesi väriluokkia. Jos haluat nyt tulostaa luettelot tehtävistäsi eri luokilla eri sivuilla, lue lisää. Seuraavassa esitämme sinulle 2 tapaa saada se.

Tapa 1: Tulosta tehtäväluettelot manuaalisesti yksi kerrallaan

1. Ensinnäkin, avaa Outlookissa Tasks-ruutu.
2. Avaa sitten Tehtävä-kansio.
3. Aktivoi sitten "Haku" -nauha painamalla "Ctrl + E".
4. Napsauta sen jälkeen "Haku" -välilehdessä "Luokittele" -painiketta.
5. Valitse avattavasta luettelosta väriluokka.
6. Sitten vain valitun luokan tehtävät jätetään luetteloon.
7. Tulosta nyt tehtäväluettelo siirtymällä kohtaan Tiedosto> Tulosta.
8. Tulosta sitten samalla tavalla muiden väriluokkien tehtäväluettelot yksitellen manuaalisesti.

Tapa 2: Erä tulosta VBA: n tehtäväluettelot

1. Käynnistä VBA-editori heti alusta alkaenKuinka suorittaa VBA-koodi Outlookissa".
2. Lisää sitten viite "MS Excel Object Library "kuten"Objektin lisääminen Library Viite VBA: ssa".
3. Kopioi seuraavaksi seuraava VBA-koodi moduuliin.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Sen jälkeen paina “F5” -näppäintä suorittaaksesi tämän makron heti.
5. Kun makro on valmis, luettelot eri luokkiin kuuluvista tehtävistä tulostetaan eri sivuille seuraavan kuvakaappauksen mukaisesti.

Hanki arvokkaita tietoja vaarantuneesta PST-tiedostosta

Jos PST-tiedosto ei ole käytettävissä, seuraava askelsi on epäilemättä PST-korjaus. Tässä tapauksessa voit ensin kokeilla postilaatikon korjaustyökalua. Jos se epäonnistuu, voit kokeilla toista ulkoista työkalua, kuten DataNumen Outlook Repair. Se pystyy palauttamaan PST-tiedot nopeasti.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien palauta mdf ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com