2 nopeaa tapaa löytää tai poistaa lauseita, jotka sisältävät tiettyä tekstiä Wordissasi

Tässä artikkelissa tarjoamme sinulle kaksi nopeaa tapaa etsiä tai poistaa lauseita, jotka sisältävät tiettyä tekstiä Wordissasi.

Kaikki tietävät, että voimme käyttää Wordin "Etsi ja korvaa" -toimintoa löytääksemme helposti kaikki tiettyjen sanojen esiintymät. Sitten meillä ei ole ongelmia korostaa, korvata tai poistaa niitä. Kuten näette, kohde on sana tai lause. Tänään kuitenkin kerromme mielellämme makrotavasta löytää tai poistaa tiettyä tekstiä sisältäviä lauseita.

Tapa 1: Etsi tai poista tiettyä tekstiä sisältäviä lauseita

1. Aloita painamalla "Alt + F11" käynnistääksesi VBA-editorin Wordissa.
2. Luo sitten uusi moduuli napsauttamalla “Normal”.
3. Napsauta sitten Lisää ja valitse Moduuli saadaksesi uuden.
4. Ja avaa moduuli kaksoisnapsauttamalla.
5. Liitä nyt seuraavat koodit:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Napsauta sitten "Suorita".
7. Tulee syöttöruutu, jossa sinua pyydetään syöttämään tekstiä. Kirjoita vain yhteinen teksti, jonka kaikki lauseet sisältävät. Napsauta “OK”.
8. Sitten näet lauseen, joka sisältää valitun tekstin ja kehotettavan viestiruudun. Napsauta ”Kyllä” poistaaksesi lauseen ja ”Ei” pitääksesi sen.
9. Vahvistuksen jälkeen seuraava lause, jolla on määrätty teksti, on valittuna. Ja vahvistusruutukin on olemassa. Makro nimittäin vie sinut askel askeleelta läpi koko dokumentin, etsii kohdelauseita ja kysyy vahvistustasi joka kerta.

Tapa 2: Etsi tai poista luettelossa olevaa tekstiä sisältäviä lauseita

Menetelmän 1 makron avulla voit etsiä vain yhtä sanaa tai ilmausta kerrallaan. Voit varmasti suorittaa makron toistuvasti etsiäksesi useita sanoja tai lauseita. Tarjoamme sinulle uuden makron vastaamaan useiden hakujen tarpeeseen.

1. Lisää ensin kaikki kohdetekstit uuteen asiakirjaan. Varmista, että jokainen tekstinpätkä täyttää yhden kappaleen ilman välilyöntiä. Sulje ja tallenna asiakirja.
2. Seuraavaksi asenna ja suorita makro tarkat vaiheet menetelmässä 1.
3. Korvaa sitten makro tällä:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Nyt ”Selaa” -ikkuna avautuu. Valitse juuri tallennettu asiakirja ja napsauta "Avaa".
5. Seuraava menettely on sama kuin menetelmässä 1.

Lähestymistapa vioittuneiden asiakirjojen käsittelyyn

Arvokkaiden tietojen menetys on ehdottoman tuhoisa. Se voi jopa jättää yrityksesi vaakalaudalle. Tällaisen turhautumisen välttämiseksi sinun täytyy saada käsiinsä a Sanakorjaus työkalu mahdollisimman pian. Tällainen työkalu auttaa sinua voittamaan taistelun asiakirjojen vioittumisen kanssa.

Tekijän esittely:

Vera Chen on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjaa Excel ja pdf korjata ohjelmistotuotteita. Lisätietoja osoitteessa www.datanumen.com