2 nopeaa tapaa poimia yksittäisiä sivuja Word-asiakirjastasi

Tämän päivän viestissä haluamme jakaa kanssasi kaksi nopeaa tapaa poimia yksittäisiä sivuja Word-dokumentistasi.

Joskus Word-asiakirjassa jokainen sivu voi sisältää melko itsenäistä sisältöä, kuten taulukon. Ja sinun on todennäköisesti lähetettävä erilaisia ​​taulukoita eri ihmisille. Sitten sinun on tallennettava kukin taulukko, joka on jokainen sivu, erillisenä tiedostona.

Ensimmäisen ajatuksen tulee mielestämme olla klassinen copy-and-paste. Silti kaikki, mikä liittyy valintaan, voi olla joskus ärsyttävää, sillä vetäminen ja valitseminen voi helposti tehdä päät ilman valintaa. Tästä syystä suosittelemme sinulle kahta nopeaa tapaa käyttää makroa työn tekemiseen.

Tapa 1: Pura nykyinen sivu ja tallenna se uutena asiakirjana

1. Ensinnäkin, aseta kursori sivulle, jonka haluat poimia.
2. Napsauta Kehittäjä-välilehteä ja napsauta sitten Visual Basic kutsuttaaksesi VBA-editorin. Jos “Kehittäjä” ei ole aktivoitu, paina sen sijaan vain “Alt + F11”.
3. Toiseksi siirry Normal-projektiin napsauttamalla sitä.
4. Napsauta sitten Lisää-välilehteä ja valitse Moduuli.
5. Kaksoisnapsauta uutta moduulia avataksesi muokkausalueen.
6. Liitä sitten seuraavat koodit sinne:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Napsauta lopuksi Suorita-painiketta.

Nyt on 2 syöttöruutua. Kirjoita polku, johon haluat tallentaa uuden asiakirjan, ensimmäiseen syöttöruutuun. Ja kirjoita uusi asiakirjan nimi toiseen.

Tapa 2: Pura kukin sivu ja tallenna se uutena asiakirjana

Seuraavan makron avulla voit purkaa asiakirjan jokaisen yksittäisen sivun.

1. Ensinnäkin, paina "Ctrl + Koti" siirtyäksesi asiakirjan alkuun.
2. Noudata sitten samoja ohjeita menetelmässä 1 makron asentamiseksi ja suorittamiseksi.
3. Tällä kertaa korvaa makro tällä:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Käsittele sanakysymyksiä

Wordissa on ja tulee aina olemaan erilaisia ​​ongelmia. Tarkoituksena on oppia korjaamaan ne oikein. Suositeltavin tapa on tietenkin hankkia hienostunut Sanojen palautus työkalu. Sinun tulisi tarttua joka minuutti tietojen palauttamiseksi ennen kuin on liian myöhäistä.

Tekijän esittely:

Vera Chen on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korruptoitunut xlsx ja pdf korjata ohjelmistotuotteita. Lisätietoja osoitteessa www.datanumen.com