2 nopeaa tapaa viedä kaikkien merkittyjen Outlook-sähköpostiviestien luettelo Exceliin

Jos haluat viedä kaikkien merkittyjen sähköpostien luettelon Outlook-postilaatikostasi Exceliin, voit käyttää jompaa kumpaa tässä artikkelissa jaettua tapaa.

Esimerkiksi, jos haluat käsitellä kaikkia merkittyjä sähköposteja nopeammin tai jakaa ne jonkun muun kanssa, voit toivoa vievän ne Excel-laskentataulukkoon. Tässä esitellään kaksi lähestymistapaa sen toteuttamiseksi. Edellinen käyttää tavallista "Tuo ja vie" -ominaisuutta löydettyään merkittyjä sähköposteja. Ollakseni rehellinen, se on vähän ikävä. Siksi jälkimmäisessä opetamme sinulle helpomman tavan käyttää VBA: ta.

Tapa 1: Vie kaikki löydetyt merkityt sähköpostit manuaalisesti

1. Napsauta ensin postitusluettelon yläpuolella olevaa hakukenttää.
2. Napsauta sitten ”Kaikki postikohdat” ”Etsi” -välilehden ”Laajuus” -ryhmässä.
3. Napsauta seuraavaksi Määritä-ryhmän Merkitty-painiketta.
4. Kun kaikki luettelossa näkyvät ilmoitetut sähköpostit, valitse yksi sähköposti ja valitse kaikki painamalla "Ctrl + A".
5. Paina sitten ”Ctrl + Vaihto + V” -näppäimen pikanäppäimiä.
6. Luo uusi kansio uudessa valintaikkunassa Outlook-tiedostoon.
7. Valitse myöhemmin uusi luotu kansio ja napsauta “OK”, joka siirtää kaikki löydetyt merkityt sähköpostit uuteen kansioon.
8. Napsauta sen jälkeen "Tiedosto"> "Avaa"> "Tuo",
9. Valitse ponnahdusvalintaikkunassa "Vie tiedostoon"> "Seuraava"> "Microsoft Excel 97-2003"> "Seuraava".
10. Valitse uudessa näytössä oikea kansio ja paina Seuraava.
11. Suorita vienti loppuun noudattamalla ohjattuja toimintoja.
12. Saat uuden Excel-tiedoston, joka näkyy seuraavana kuvakaappauksena.

Tapa 2: Vie luettelo kaikista merkittyistä sähköposteista VBA: n kautta

1. Käynnistä VBA-editori painamalla Outlookissa ”Alt + F11”.
2. Ota sitten käyttöön "MS Excel Object" kohdan "Objektikirjastoviittauksen lisääminen VBA:ssa".
3. Kopioi seuraavaksi alla oleva VBA-koodi moduuliin.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Laita lopuksi kohdistin "ExportAllFlaggedEmailsToExcel" -alirutiiniin ja paina "F5" -näppäintä.
5. Valitse sitten Outlook-tiedosto uudesta valintaikkunasta.
6. Kun saat "Valmiit" -kehotteen, saat myös uuden Excel-tiedoston, kuten alla olevan kuvan.

Suojaa Outlook korruptiolta

Outlook on altis virheille ja korruptiolle, joten Outlook-tietojemme suojaaminen on meille erittäin vaikea tehtävä. Epäilemättä tehokkain ja käytännöllisin tapa on tehdä säännöllisiä varmuuskopioita Outlookille. Sen lisäksi meidän on myös hankittava tehokas ja luotettava Outlook-korjaustyökalu, kuten DataNumen Outlook Repair. Se tulee käteväksi, jos Saapuneet-kansion korjaustyökalu ei vaikuta.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien korjata SQL Server ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com