2 tapaa erän poistaa kaikki yhteystiedot ilman sähköpostiosoitetta Outlookissa

Jos huomaat, että joillakin yhteystiedoilla ei ole sähköpostiosoitetta Outlookissasi, voit halutessasi käsitellä jokaisen yhteystietokansion poistaaksesi kaikki tällaiset yhteystiedot. Tässä viestissä jaetaan kaksi tapaa.

Ehkä sinulla on monia yhteystietoja Outlookissa ja joillakin heistä ei ole sähköpostiosoitetta. Jos luulet, että niistä ei ole enää hyötyä, sinun on toivottavasti poistettava kaikki yhteystiedot ilman sähköpostiosoitetta. Tavallisella tavalla voit käyttää pikahakua löytääksesi ne ja poistaa ne sitten manuaalisesti, kuten seuraava menetelmä 1. Silti se on vähän tylsiä. Siksi menetelmässä 2 opetamme sinulle toisen tehokkaamman tavan.

Tapa 1: Poista manuaalisesti, kun olet löytänyt yhteystietoja ilman sähköpostiosoitetta

1. Aloita painamalla “Ctrl + 3” -näppäinyhdistelmää päästäksesi “Yhteystiedot”-ruutuun.
2. Napsauta sitten hakukenttää.
3. Napsauta sitten uudessa "Hae" -nauhassa "Kaikki yhteystiedot".
4. Napsauta sitten ”Osoite”> “Onko sähköpostiosoite”.
5. Sen jälkeen "EI sähköpostiosoitteet: = []" -ehto lisätään hakukenttään. Sinun on poistettava ”EI”.
6. Myöhemmin kaikki yhteystiedot, joilla ei ole sähköpostiosoitetta, luetellaan.
7. Nyt sinun pitäisi valita yhteystiedot hakutuloksista manuaalisesti siten, että yhteystietoryhmiesi on oltava myös luettelossa.
8. Paina lopuksi "Del" -näppäintä poistaaksesi kaikki valitut yhteystiedot.

Tapa 2: Erä Poista kaikki yhteystiedot ilman sähköpostiosoitetta VBA: lla

1. Napauta ensin ”Alt + F11” käynnistääksesi VBA-editorin Outlookissa.
2. Kopioi seuraava VBA-koodi uudessa näytössä moduuliin.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Napsauta myöhemmin "BatchDeleteAllContactsWithoutEmailAddress" -alirutiinia.
4. Lopulta paina “F5” käynnistääksesi tämän makron.
5. Kun se on valmis, saat viestin tuloksista, kuten alla olevan kuvan.
6. Kaikki yhteystiedot ilman sähköpostiosoitetta on siirretty Poistetut-kansioon.

Pidä kaukana kaikista mahdollisista riskeistä

Outlook voi vahingoittua useista tekijöistä, kuten viruksista, käyttäjävirheistä, ohjelmistovirheistä ja laitteistovikoista. Sinun on oltava haluttomia kokemaan Outlook-vahinkoja, joten sinun on pidettävä kaikki nämä mahdolliset riskit loitolla. Esimerkiksi sinun on asennettava tehokas virustentorjuntaohjelmisto tietokoneellesi. Lisäksi sinun on varmuuskopioitava Outlook-tiedot säännöllisesti. Viimeisenä mutta ei vähäisimpänä, sinun on parasta valmistaa vankka ja luotettava korjaustyökalu, kuten DataNumen Outlook Repair. Se voi korjata korruptoitunut PST tiedosto helposti.

Tekijän esittely:

Shirley Zhang on tietojen palauttamisen asiantuntija DataNumen, Inc., joka on maailman johtava tietojen palautustekniikoissa, mukaan lukien SQL Server korruptio ja Outlookin korjausohjelmistotuotteet. Lisätietoja osoitteessa www.datanumen.com