Πώς να εξάγετε γρήγορα έναν φάκελο Outlook με όλους τους υποφακέλους και στοιχεία σε έναν φάκελο των Windows

Κατά καιρούς, μπορεί να θέλετε να εξαγάγετε μαζικά έναν φάκελο Outlook με όλους τους υποφακέλους και τα στοιχεία σε ένα φάκελο Windows. Αυτό το άρθρο θα σας διδάξει μια τέτοια μέθοδο που εφαρμόζει το Outlook VBA.

Όταν θέλετε να εξάγετε έναν φάκελο Outlook στην τοπική μονάδα δίσκου με όλα τα στοιχεία στην ίδια δομή φακέλου, αν επιλέξετε να αποθηκεύσετε και να εξάγετε με μη αυτόματο τρόπο, θα σας πάρει πολύ χρόνο. Έτσι, γιατί δεν καταφεύγετε σε άλλα μέσα, όπως εργαλεία εξαγωγής ή κωδικούς VBA; Εδώ θα σας αποκαλύψουμε ένα τέτοιο κομμάτι κώδικα VBA. Θα σας επιτρέψει να το πετύχετε σαν αεράκι.

Εξαγωγή όλων των υποφακέλων και στοιχείων σε έναν φάκελο Outlook σε ένα φάκελο Windows

1. Από την αρχή, ξεκινήστε το πρόγραμμα Outlook.
2. Στη συνέχεια, στο κύριο παράθυρο του Outlook, πατήστε τις συντομεύσεις πλήκτρων "Alt + F11".
3. Στη συνέχεια, θα εμφανιστεί το παράθυρο "Microsoft Visual Basic for Applications".
4. Στη συνέχεια, πρέπει να ανοίξετε μια κενή μονάδα και να αντιγράψετε τους ακόλουθους κωδικούς VBA σε αυτήν.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Μετά από αυτό, πρέπει να βεβαιωθείτε ότι το Outlook σας επιτρέπει μακροεντολές στις ρυθμίσεις μακροεντολής.
6. Τελικά, μπορείτε να δοκιμάσετε.

• Πρώτον, πίσω στο νέο παράθυρο μακροεντολής.
• Επόμενο κλικ στην υπορουτίνα "ExportFolderWithAllItems".
• Στη συνέχεια, πατήστε το πλήκτρο F5 για να εκτελέσετε αυτήν τη μακροεντολή.
• Μετά από αυτό, πρέπει να επιλέξετε έναν συγκεκριμένο φάκελο.
• Τέλος, όταν λάβετε ένα μήνυμα που λέει "Ολοκλήρωση", μπορείτε να αποκτήσετε πρόσβαση στον προκαθορισμένο τοπικό φάκελο. Θα βρείτε ότι όλα τα στοιχεία έχουν αποθηκευτεί στην ίδια δομή φακέλου.

Αποτρέψτε την απώλεια δεδομένων από καταρρεύσεις του Outlook

Ίσως να έχετε αντιμετωπίσει ποτέ πολλά σφάλματα του Outlook. Τις περισσότερες φορές, μετά από μια επανεκκίνηση, το Outlook θα μπορεί να λειτουργεί κανονικά. Ωστόσο, υπάρχει επίσης η περίπτωση το αρχείο PST μας να καταστραφεί. Σε αυτήν την περίπτωση, θα προσπαθήσετε όσο το δυνατόν καλύτερα να ανακτήσετε τα δεδομένα PST σας, όπως επαναλαμβάνοντας ένα έμπειρο εργαλείο όπως DataNumen Outlook Repair. Είναι σε θέση να επιδιορθώστε το Outlook σφάλματα και εξαγωγή δεδομένων από παραβιασμένο αρχείο PST χωρίς να ιδρώνετε.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων SQL Server επισκευή και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com