Πώς να εξαγάγετε γρήγορα τις πληροφορίες μεγέθους όλων των φακέλων σε ένα αρχείο PST σε ένα αρχείο Excel

Εάν θέλετε να ελέγξετε τις πληροφορίες μεγέθους κάθε φακέλου σε ένα αρχείο PST, μπορείτε να χρησιμοποιήσετε τη μέθοδο που εκτίθεται σε αυτό το άρθρο. Θα εξαγάγει γρήγορα τις πληροφορίες μεγέθους όλων των φακέλων σε ένα αρχείο PST σε ένα αρχείο Excel.

Όταν το αρχείο PST είναι πολύ μεγάλο, ίσως θέλετε να ελέγξετε το μέγεθος κάθε φακέλου. Θα σας βοηθήσει να καταλάβετε εύκολα ποια είναι τα μεγαλύτερα και να κάνετε την κατάλληλη αρχειοθέτηση με βάση το μέγεθος. Γενικά, για να ελέγξετε το μέγεθος του φακέλου, μπορείτε απλά να κάνετε δεξί κλικ σε έναν φάκελο και στη συνέχεια να επιλέξετε «Ιδιότητες». Στο νέο αναδυόμενο παράθυρο διαλόγου, μπορείτε να κάνετε κλικ στο κουμπί "Μέγεθος φακέλου". Ωστόσο, εάν έχετε δημιουργήσει πολλούς φακέλους, ο χειροκίνητος έλεγχος των πληροφοριών μεγέθους μία προς μία είναι πολύ ενοχλητικός. Έτσι, εάν θέλετε να λάβετε ομαδικά τις πληροφορίες μεγέθους όλων των φακέλων σε ένα αρχείο PST, μπορείτε να χρησιμοποιήσετε τον ακόλουθο κώδικα VBA. Θα εξαγάγει όλα τα ονόματα φακέλων και τις πληροφορίες μεγέθους σε ένα αρχείο Excel με μία κίνηση.

Εξάγετε τις πληροφορίες μεγέθους όλων των φακέλων σε ένα αρχείο PST σε ένα αρχείο Excel

1. Για να ξεκινήσετε, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, μεταβείτε στην καρτέλα "Προγραμματιστής" και κάντε κλικ στο κουμπί "Visual Basic" ή πατήστε τα πλήκτρα "Alt + F11" για πρόσβαση στον επεξεργαστή VBA.
3. Στη συνέχεια, στο παράθυρο "Microsoft Visual Basic for Applications", ανοίξτε μια λειτουργική μονάδα που δεν χρησιμοποιείται.
4. Στη συνέχεια, αντιγράψτε και επικολλήστε τους ακόλουθους κωδικούς VBA σε αυτήν την ενότητα.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Μετά από αυτό, πρέπει να ορίσετε το επίπεδο ασφάλειας μακροεντολής του Outlook σε χαμηλό.
6. Τελικά, μπορείτε να δοκιμάσετε.

• Πατήστε το πλήκτρο F5 στο τρέχον παράθυρο μακροεντολής.
• Στη συνέχεια, θα σας ζητηθεί να επιλέξετε ένα αρχείο PST, όπως η παρακάτω εικόνα:
• Αφού επιλέξετε ένα αρχείο προέλευσης, το Outlook θα αρχίσει να εξάγει τις πληροφορίες μεγέθους στο Excel.
• Μετά την ολοκλήρωση της μακροεντολής, λαμβάνετε ένα μήνυμα όπως το παρακάτω στιγμιότυπο οθόνης.
• Τέλος, θα μπορείτε να βρείτε το αρχείο Excel στον προκαθορισμένο τοπικό φάκελο. Το αρχείο Excel θα έχει την εξής μορφή:

Αντιμετωπίστε τα συχνά σφάλματα PST

Δεδομένου ότι το Outlook είναι επιρρεπές σε σφάλματα, μπορεί να έχετε αντιμετωπίσει πολλά προβλήματα στο Outlook σας. Προκειμένου να αντιμετωπίσετε καλύτερα και πιο ευέλικτα τα ενοχλητικά προβλήματα PST, συνιστάται να έχετε κοντά σας ένα έμπειρο και αξιόπιστο βοηθητικό πρόγραμμα επισκευής, όπως π.χ. DataNumen Outlook Repair. Είναι σε θέση να επιδιορθώστε το PST προβλήματα σαν αεράκι.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων SQL Server ανάκτηση και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com