Τρόπος γρήγορης εξαγωγής όλων των συνημμένων εικόνων ενός email του Outlook σε ένα φύλλο εργασίας του Excel

Εάν θέλετε να εξάγετε γρήγορα όλα τα συνημμένα εικόνων ενός email του Outlook σε ένα φύλλο εργασίας του Excel, μπορείτε να ανατρέξετε σε αυτό το άρθρο. Εδώ θα σας δείξουμε έναν πιο αποτελεσματικό τρόπο από τη μη αυτόματη εξαγωγή.

Όταν λαμβάνετε ένα email που περιέχει πλήθος συνημμένων εικόνων, αν θέλετε να τις χρησιμοποιήσετε για τη δημιουργία μιας αναφοράς στο Excel, θα πρέπει να αναζητήσετε έναν τρόπο εξαγωγής αυτών των εικόνων σε ένα φύλλο εργασίας του Excel σε παρτίδες. Στη συνέχεια, θα σας παρουσιάσουμε μια τέτοια προσέγγιση.

Εξαγωγή όλων των συνημμένων εικόνων ενός email σε φύλλο εργασίας του Excel

1. Αρχικά, αποκτήστε πρόσβαση στην εφαρμογή Outlook με κανονικό τρόπο.
2. Στη συνέχεια, στο παράθυρο του Outlook, πατήστε "Alt + F11" συντομεύσεις πλήκτρων, οι οποίες θα εμφανίσουν το παράθυρο "Microsoft Visual Basic for Applications".
3. Σε αυτήν την οθόνη, πρέπει να ανοίξετε μια ενότητα που δεν χρησιμοποιείται ή να εισαγάγετε μια νέα ευθεία.
4. Στη συνέχεια, θα πρέπει να αντιγράψετε το παρακάτω κομμάτι του κώδικα VBA σε αυτήν την ενότητα.

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Μετά από αυτό, μπορείτε να βγείτε από τη μακροεντολή.
6. Στη συνέχεια, μεταβείτε στο "Αρχείο"> "Επιλογές"> "Γραμμή εργαλείων γρήγορης πρόσβασης" για να προσθέσετε αυτήν τη μακροεντολή στη γραμμή εργαλείων γρήγορης πρόσβασης.
7. Τέλος, μπορείτε να δοκιμάσετε αυτήν τη μακροεντολή τώρα.

• Αρχικά, επιλέξτε ή ανοίξτε ένα email προέλευσης.
• Στη συνέχεια, κάντε κλικ στο κουμπί μακροεντολής στη γραμμή εργαλείων γρήγορης πρόσβασης.
• Όταν ολοκληρωθεί η μακροεντολή, θα λάβετε ένα φύλλο εργασίας του Excel, όπως το παρακάτω στιγμιότυπο οθόνης:

Προστατέψτε το αρχείο Outlook από το να καταστραφεί

Είναι γνωστό ότι το Outlook είναι επιρρεπές σε διαφθορά. Επομένως, πρέπει να καταλάβουμε πώς να προστατεύσουμε το Outlook από τη διαφθορά. Πρώτα απ 'όλα, για να αποκλείσετε τις επιθέσεις ιών, είναι απαραίτητο να εγκαταστήσετε λογισμικό προστασίας από ιούς και να μην κατεβάσετε ποτέ άγνωστο συνημμένο. Εκτός αυτού, καλύτερα να αποκτήσουμε ένα ισχυρό εργαλείο επισκευής, όπως DataNumen Outlook RepairΜπορεί να προσφέρει την πιο αποτελεσματική θεραπεία σε περίπτωση Διαφθορά στο Outlook.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com