Πώς να εξάγετε γρήγορα όλους τους υπερσυνδέσμους σε πολλαπλά μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook στο Excel

Όταν χρειάζεται να εξαγάγετε όλους τους υπερσυνδέσμους σε ένα ή περισσότερα email, είναι ανόητο να τους αντιγράψετε έναν προς έναν. Αυτή η ανάρτηση θα σας διδάξει μια μέθοδο για την γρήγορη εξαγωγή όλων των υπερσυνδέσμων σε πολλά email στο Excel.

Για ορισμένους λόγους, όπως η καταγραφή των υπερσυνδέσμων σε όλα τα μηνύματα που έχετε στείλει, θα πρέπει να εξαγάγετε τους υπερσυνδέσμους. Χωρίς αμφιβολίες, δεν είναι σκόπιμο να τα εξαγάγετε και να τα αντιγράψετε χειροκίνητα. Πρέπει να επιθυμείτε μια πολύ πιο έξυπνη προσέγγιση, όπως η χρήση του VBA. Εδώ θα σας μοιραστούμε ένα τέτοιο κομμάτι κώδικα VBA, το οποίο είναι σε θέση να εξάγει όλους τους υπερσυνδέσμους σε πολλά email στο Excel με ένα εύκολο κλικ.

Εξαγωγή όλων των υπερσυνδέσμων σε πολλαπλά μηνύματα ηλεκτρονικού ταχυδρομείου στο Excel

1. Για να ξεκινήσετε, ξεκινήστε το πρόγραμμα Outlook ως συνήθως.
2. Στη συνέχεια, στο παράθυρο του Outlook, πρέπει να πατήσετε τα πλήκτρα "Alt + F11".
3. Αμέσως, θα έχετε πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA.
4. Στη συνέχεια, πρέπει να ενεργοποιήσετε τη «Βιβλιοθήκη αντικειμένων Microsoft Word» καθώς και τη «Βιβλιοθήκη αντικειμένων Microsoft Excel». Κάντε κλικ στα «Εργαλεία» > «Αναφορές» και, στη συνέχεια, ενεργοποιήστε τα στο αναδυόμενο παράθυρο διαλόγου.
5. Στη συνέχεια, πρέπει να ανοίξετε μια αχρησιμοποίητη μονάδα, στην οποία πρέπει να αντιγράψετε τον παρακάτω κώδικα VBA σε αυτήν την ενότητα.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Μετά από αυτό, μπορείτε να βγείτε από το τρέχον παράθυρο του προγράμματος επεξεργασίας VBA.
7. Αργότερα αποκτήστε πρόσβαση στο "Επιλογές Outlook" για να προσαρμόσετε τη Γραμμή εργαλείων γρήγορης πρόσβασης για να προσθέσετε τη μακροεντολή που προστέθηκε πρόσφατα στη Γραμμή εργαλείων γρήγορης πρόσβασης.
8. Τέλος, μπορείτε να τραβήξετε μια φωτογραφία:

• Πρώτα απ 'όλα, στη λίστα email, επιλέξτε τα email των οποίων οι υπερσύνδεσμοι θέλετε να εξαγάγετε.
• Στη συνέχεια, κάντε κλικ στο κουμπί μακροεντολής στη γραμμή εργαλείων γρήγορης πρόσβασης.
• Όταν ολοκληρωθεί η μακροεντολή, θα λάβετε ένα αρχείο Excel, όπως η παρακάτω εικόνα:

Επιδιόρθωση μη αναμενόμενων ζητημάτων του Outlook

Προβλήματα με το Outlook μπορεί να προκύψουν κατά καιρούς χωρίς κανένα σημάδι. Ωστόσο, όσον αφορά τα μικρά σφάλματα, το Outlook μπορεί να αποκατασταθεί με μια απλή επανεκκίνηση ή... εργαλείο επισκευής εισερχομένων. Αλλά εάν αντιμετωπίζετε κάποια σοβαρά προβλήματα, τα εσωτερικά μέσα δεν θα έχουν αποτελέσματα. Σε αυτό το σημείο, η τελευταία σας λύση είναι σίγουρα ένα πιο αξιόπιστο και ισχυρό εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com