Τρόπος ορισμού διαφορετικού προεπιλεγμένου χρόνου υπενθύμισης για διαφορετικά είδη επισημασμένων στοιχείων στο Outlook

Από προεπιλογή, το Outlook θα χρησιμοποιεί αυτόματα τον προεπιλεγμένο χρόνο υπενθύμισης των εργασιών σε όλα τα είδη των επισημασμένων στοιχείων. Ωστόσο, εάν θέλετε να χρησιμοποιήσετε διαφορετικό χρόνο υπενθύμισης για επισημασμένα στοιχεία με βάση τον τύπο στοιχείου, μπορείτε να ανατρέξετε στη μέθοδο που παρουσιάζεται σε αυτό το άρθρο.

Το Outlook σάς επιτρέπει να ορίσετε τον προεπιλεγμένο χρόνο υπενθύμισης για όλα τα επισημασμένα στοιχεία, ανεξάρτητα από τον τύπο του αντικειμένου. Μπορείτε να μεταβείτε στο μενού "Αρχείο" και να κάνετε κλικ στο "Επιλογές". Στη συνέχεια, στο παράθυρο "Επιλογές Outlook", μπορείτε να δείτε την επιλογή "Προεπιλεγμένος χρόνος υπενθύμισης" στην καρτέλα "Εργασίες", όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.

Παρ 'όλα αυτά, οι περισσότεροι χρήστες ελπίζουν να χρησιμοποιούν διαφορετικό χρόνο υπενθύμισης για διαφορετικά είδη στοιχείων με σημαία, όπως "9:00" για μηνύματα με σημαία και "17:30" για επαφές με σημαία. Στη συνέχεια, θα επικεντρωθούμε σε αυτό το παράδειγμα για να παρουσιάσουμε μια μέθοδο.

Ορίστε διαφορετικό προεπιλεγμένο χρόνο υπενθύμισης για διαφορετικά είδη επισημασμένων αντικειμένων

1. Για να ξεκινήσετε, ανοίξτε την εφαρμογή Outlook.
2. Στη συνέχεια, αποκτήστε πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA με αναφορά στο "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
3. Στο επόμενο παράθυρο "Microsoft Visual Basic for Applications", αντιγράψτε τον ακόλουθο κώδικα στο έργο "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Στη συνέχεια, επανεκκινήστε το Outlook για να ενεργοποιήσετε αυτήν τη μακροεντολή.
5. Από τώρα και στο εξής, κάθε φορά που επισημαίνετε ένα μήνυμα ηλεκτρονικού ταχυδρομείου, η ώρα υπενθύμισης ορίζεται σε "10:00" την ημερομηνία λήξης της σημαίας.
6. Και όταν επισημαίνετε μια επαφή, η ώρα υπενθύμισης θα οριστεί σε "17:30" την ημερομηνία λήξης της σημαίας.

Αντιμετωπίστε με ευελιξία τα προβλήματα του Outlook

Μπορείτε να αντιμετωπίσετε κάθε είδους προβλήματα στο Outlook σας. Επομένως, πρέπει να μάθετε ορισμένα μέτρα για να τα αντιμετωπίσετε εκ των προτέρων. Για παράδειγμα, εάν το Outlook σας επανεκκινείται συχνά, πρέπει να επιδιορθώσετε το Office ή να απενεργοποιήσετε τα πρόσθετα τρίτων κ.λπ. Ή εάν το Outlook PST σας παραβιαστεί, μπορείτε πρώτα να δοκιμάσετε το εργαλείο επισκευής εισερχομένων. Όταν αποτύχει, μπορείτε να συνεχίσετε να καταφεύγετε σε ένα ισχυρό εξωτερικό εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com