Τρόπος γρήγορης εξαγωγής όλων των παραληπτών από αρχεία πολλαπλών μηνυμάτων Outlook (.msg)

Ορισμένοι χρήστες θα ήθελαν να εξαγάγουν γρήγορα όλους τους παραλήπτες από πολλά αρχεία μηνυμάτων Outlook που έχουν αποθηκευτεί από μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook. Τώρα, αυτό το σost θα το εξετάσει για να μοιραστεί μια γρήγορη προσέγγιση.

Για να εξαγάγετε τους παραλήπτες από ένα μόνο αρχείο μηνυμάτων του Outlook, μπορείτε απλώς να κάνετε διπλό κλικ για να το ανοίξετε και, στη συνέχεια, να αντιγράψετε τους παραλήπτες στο ανοιχτό παράθυρο μηνύματος. Ωστόσο, εάν πρέπει να αντιμετωπίσετε μια δέσμη αρχείων μηνυμάτων του Outlook, η μη αυτόματη μέθοδος δεν είναι αρκετά αποτελεσματική. Έτσι, μπορείτε να αναζητήσετε έναν πολύ πιο αποτελεσματικό τρόπο. Εδώ θα σας παρουσιάσουμε ένα τέτοιο. Διαβάστε παρακάτω για να λάβετε τις λεπτομέρειες.

Εξαγωγή όλων των παραληπτών από αρχεία πολλαπλών μηνυμάτων Outlook (.msg)

1. Για ωςtart, αποκτήστε πρόσβαση στο πρόγραμμα επεξεργασίας του Outlook VBA σύμφωνα με το "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
2. Στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα VBA σε μια κενή μονάδα.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Στη συνέχεια, μετακινήστε τον κέρσορα στην πρώτη υπορουτίνα.
4. Στη συνέχεια, κάντε κλικ στο κουμπί "Εκτέλεση" ή πατήστε το πλήκτρο "F5".
5. Στη συνέχεια, στο αναδυόμενο παράθυρο διαλόγου, επιλέξτε το φάκελο των Windows που περιέχει τα αρχεία μηνυμάτων προέλευσης Outlook (.msg).
6. Αφού επιλέξετε, κάντε κλικ στο "OK" για να αφήσετε τη μακροεντολή να συνεχίσει να λειτουργεί.
7. Όταν ολοκληρωθεί η μακροεντολή, θα εμφανιστεί ένα μήνυμα που θα εμφανίζει όλες τις διευθύνσεις email όλων των εξαγόμενων παραληπτών, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.

Προστατέψτε τα δεδομένα του Outlook από το Jeopardy

Τα δεδομένα του Outlook είναι ομοίως επιρρεπή σε διαφθορά. Ως εκ τούτου, είναι ένα πολύ επαχθές καθήκον να προστατεύσουμε τα δεδομένα του Outlook. Απαιτεί από εσάς να επιμείνετε στην τακτική δημιουργία αντιγράφων ασφαλείας για τα δεδομένα του Outlook. Επίσης, εάν είναι δυνατόν, είναι συνετό και συνιστάται η προετοιμασία ενός έμπειρου και επαγγελματικού Outlook Επισκευή PST εργαλείο, όπως DataNumen Outlook Repair, ώστε να έχετε άμεση και έγκαιρη διάσωση σε περίπτωση διαφθοράς του Outlook.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση Sql Server και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com