Πώς να επισημαίνετε αυτόματα τα ραντεβού του Σαββατοκύριακου ως ιδιωτικά στο Outlook

Λύσεις του Outlook Σεπτέμβριος 29, 2025

Για μost χρήστες, τα ραντεβού που προγραμματίζονται το Σαββατοκύριακο είναι συνήθως ιδιωτικά. Ως εκ τούτου, θέλουν το Outlook να επισημαίνει και να εμφανίζει αυτόματα τέτοιες συναντήσεις ως ιδιωτικές. Σε αυτό το άρθρο, θα το κάνουμε πραγματικότητα με λίγο σενάριο.

Προκειμένου να γίνεται πιο εύκολη διάκριση μεταξύ των επαγγελματικών και των ιδιωτικών συναντήσεων, το Outlook επιτρέπει στους χρήστες να επισημαίνουν τα ραντεβού ως ιδιωτικά. Με αυτόν τον τρόπο, θα είναι αρκετά βολικό και εύκολο να εκτυπώσετε ημερολόγιο χωρίς ιδιωτικά ραντεβού. Σε αυτήν την περίπτωση, μπορεί να θέλετε το Outlook να αναγνωρίζει αυτόματα και να επισημαίνει συγκεκριμένες συναντήσεις ως ιδιωτικές. Για παράδειγμα, γενικά, τα ραντεβού το Σαββατοκύριακο είναι ιδιωτικά, επομένως θέλετε να επιτρέψετε στο Outlook να τα επισημαίνει αυτόματα ως ιδιωτικά. Στη συνέχεια, θα σας καθοδηγήσουμε να το πετύχετε.

Αυτόματη επισήμανση ραντεβού Σαββατοκύριακου ως ιδιωτικού

Αρχικά, ξεκινήστε το πρόγραμμα επεξεργασίας Outlook VBA σύμφωνα με το "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
Στη συνέχεια, στο παράθυρο "Microsoft Visual Basic for Applications", τοποθετήστε τον ακόλουθο κώδικα στο έργο "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olAppointment Then
       Set objAppointment = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    Call MarkWeedendAppointmentPrivate(objAppointment)
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    If Name = "Start" Or Name = "End" Then
       Call MarkWeedendAppointmentPrivate(objAppointment)
    End If
End Sub

Private Sub MarkWeedendAppointmentPrivate(ByVal objAppointment As Outlook.AppointmentItem)
    Dim dStartDate As Date
 
    dStartDate = Format(objAppointment.Start, "Short Date")
 
    'If the appointment start falls on weekend
    Select Case Weekday(dStartDate)
           Case 7, 1
                'Mark it private
                objAppointment.Sensitivity = olPrivate
    End Select
End Sub

Μετά από αυτό, restart Outlook για να ενεργοποιήσετε τη μακροεντολή.
Από εδώ και στο εξής, κάθε φορά που δημιουργείτε μια νέα συνάντηση ή αλλάζετε μια υπάρχουσα συνάντηση σε Σαββατοκύριακο, το Outlook θα την επισημαίνει αυτόματα ως ιδιωτική.

Επίλυση ενοχλητικών προβλημάτων του Outlook

Είναι πιθανό να αντιμετωπίσατε ορισμένα ζητήματα όταν αντιμετωπίζετε το Outlook, όπως απροσδόκητο πάγωμα εφαρμογών, μηνύματα λάθους αναδυόμενων παραθύρων και ούτω καθεξής. Όταν τα υποφέρετε, θα ανησυχούσατε. ΠΑΡΑΚΑΛΩ ηρεμησε! Ο πανικός δεν θα βοηθήσει σε τίποτα, αλλά θα επιδεινώσει την υπόθεση. Αρχικά, μπορείτε να ελέγξετε εάν μπορείτε να έχετε πρόσβαση στο αρχείο PST ως συνήθως. Εάν ναι, πρέπει να επιδιορθώσετε το αρχείο PST, το οποίο μπορεί να επιτευχθεί μέσω του εργαλείο επισκευής εισερχομένων ή ένα πιο ισχυρό εξωτερικό εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων Επισκευή MDF και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com