Πώς να εξάγετε ομαδικά πολλαπλά μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook σε ένα έγγραφο Word μέσω VBA

Εάν θέλετε να εξάγετε ομαδικά πολλά μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook σε ένα έγγραφο με ένα μόνο word, μπορείτε να χρησιμοποιήσετε τον κώδικα VBA που εμφανίζεται σε αυτό το άρθρο. Μπορεί να σας βοηθήσει να ολοκληρώσετε αυτήν την εργασία μέσα σε δευτερόλεπτα.

Έχω παρουσιάσει ποτέ πώς να μετατρέψω ένα μήνυμα ηλεκτρονικού ταχυδρομείου του Outlook σε έγγραφο του Word στο προηγούμενο άρθρο μου - "2 Αποτελεσματικές μέθοδοι για τη μετατροπή ενός μηνύματος ηλεκτρονικού ταχυδρομείου του Outlook σε έγγραφο του Word". Ωστόσο, και τα δύο μέσα που αναφέρονται στην εν λόγω σελost θα είναι αβοήθητο στην περίπτωση που θέλετε να εξάγετε ομαδικά πολλά email σε ένα έγγραφο του Word. Ως εκ τούτου, εδώ θα σας διδάξουμε έναν άλλο τρόπο. Τώρα, διαβάστε για να το πάρετε αναλυτικά.

Μαζική εξαγωγή πολλαπλών μηνυμάτων ηλεκτρονικού ταχυδρομείου του Outlook σε ένα έγγραφο Word

1. Προς starμε, ξεκινήστε το πρόγραμμα Outlook.
2. Στη συνέχεια, αφού εισέλθετε στο κύριο παράθυρο του Outlook, πρέπει να πατήσετε τα πλήκτρα "Alt + F11".
3. Στη συνέχεια θα αποκτήσετε πρόσβαση στο πρόγραμμα επεξεργασίας VBA του Outlook, στο οποίο θα πρέπει να ανοίξετε μια κενή ενότητα.
4. Στη συνέχεια, αντιγράψτε τον παρακάτω κώδικα VBA στο ανοιχτό παράθυρο της μονάδας.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Μετά από αυτό, είναι καλύτερα να προσθέσετε αυτό το νέο έργο VBA στη γραμμή εργαλείων γρήγορης πρόσβασης ή στην κορδέλα.
6. Τελικά, μπορείτε να δοκιμάσετε.

• Αρχικά, επιλέξτε πολλά μηνύματα ηλεκτρονικού ταχυδρομείου του Outlook.
• Στη συνέχεια, εντοπίστε και κάντε κλικ στο κουμπί μακροεντολής που προστέθηκε πρόσφατα.
• Αφού σας ζητηθεί "Ολοκληρώθηκε", μπορείτε να περιηγηθείτε στον προκαθορισμένο τοπικό φάκελο για να βρείτε ένα νέο έγγραφο του Word.
• Ανοίξτε αυτό το έγγραφο, στο οποίο μπορείτε να δείτε ότι έχουν εξαχθεί όλα τα επιλεγμένα email.

Κρατήστε ένα Mighty Recovery Tool κοντά

Ανεξάρτητα από τις πολυάριθμες λειτουργίες, το Outlook εξακολουθεί να μην μπορεί να είναι προστατευμένο από σφάλματα. Εάν έχετε συνηθίσει να αφήνετε τα σφάλματα μόνα τους, με αυτά να συσσωρεύονται, θα συμβεί σίγουρα η κατάρρευση του Outlook. Σε αυτό το σημείο, είναι απαραίτητο να επιστρέψετε σε ένα ισχυρό και αποτελεσματικό εργαλείο ανάκτησης, όπως DataNumen Outlook Repair. Είναι πολύ καλά Διόρθωση PST. Όσο με αυτό, δεν θα χρειάζεται πλέον να ανησυχείτε για την απώλεια δεδομένων του Outlook.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com