Τρόπος αυτόματης ρύθμισης διαφορετικού χρόνου υπενθύμισης για συσκέψεις του Outlook σε διαφορετικές κατηγορίες χρωμάτων

Εάν ταξινομείτε τις συσκέψεις του Outlook κατά κατηγορίες χρωμάτων και θέλετε να ορίσετε διαφορετική ώρα υπενθύμισης για συναντήσεις σε διαφορετικές κατηγορίες χρωμάτων, μπορείτε να ανατρέξετε σε αυτό το άρθρο. Εδώ θα σας διδάξουμε να το πραγματοποιήσετε με το Outlook VBA.

Για παράδειγμα, χωρίζετε τις συσκέψεις σε δύο ομάδες. Η μία ανήκει στην κατηγορία χρώματος "Εκτός χώρου", καθώς η τοποθεσία της σύσκεψης είναι πολύ μακριά, και η άλλη ανήκει στην κατηγορία χρώματος "Εντός χώρου", καθώς η τοποθεσία βρίσκεται ακριβώς εδώ. Τώρα, θέλετε το Outlook να μπορεί να ορίσει αυτόματα την ώρα υπενθύμισης για τη σύσκεψη "εκτός χώρου" ως 1 ώρα πριν από την έναρξη και για τη σύσκεψη "επιτόπου" ως 15 λεπτά πριν από την έναρξη. Εξετάζοντας αυτήν την απαίτηση, στη συνέχεια θα μοιραστούμε μια γρήγορη μέθοδο.

Αυτόματη ρύθμιση διαφορετικής υπενθύμισης για συναντήσεις σε διαφορετικές κατηγορίες χρωμάτων

1. Αρχικά, ξεκινήστε την εφαρμογή Outlook.
2. Στη συνέχεια, πατήστε τα πλήκτρα "Alt + F11" για πρόσβαση στο παράθυρο του προγράμματος επεξεργασίας VBA.
3. Στη συνέχεια, στο επόμενο παράθυρο, αντιγράψτε και επικολλήστε τον κώδικα VBA παρακάτω στο έργο "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Αργότερα, πρέπει να κάνετε κλικ στην υπορουτίνα "Application_Startup" και να πατήσετε το πλήκτρο "F5" για να εκτελέσετε αυτήν τη μακροεντολή.
5. Έκτοτε, κάθε φορά που προστίθεται μια νέα σύσκεψη στο προεπιλεγμένο ημερολόγιο ή αλλάζετε μια υπάρχουσα σύσκεψη, το Outlook θα ελέγχει αυτόματα τις κατηγορίες της σύσκεψης και θα ορίζει αυτόματα τη διαφορετική ώρα υπενθύμισης.

Εξάλειψη σφαλμάτων του Outlook

Κατά καιρούς ενδέχεται να προκύψουν διάφορα προβλήματα στο Outlook. Επομένως, είναι εξαιρετικά σημαντικό για τους χρήστες να μάθουν πώς να αντιμετωπίζουν τα προβλήματα του Outlook. Αρχικά, καλό είναι να δημιουργείτε τακτικά αντίγραφα ασφαλείας των δεδομένων του Outlook. Επιπλέον, εάν είναι οικονομικά προσιτό, συνιστάται να διατηρείτε ένα ισχυρό αντίγραφο ασφαλείας. Επισκευή του Outlook κοντινό εργαλείο, όπως DataNumen Outlook Repair. Μπορεί να σαρώσει το αρχείο PST για να εντοπίσει ζητήματα του Outlook και στη συνέχεια να τα επιλύσει με ευκολία.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com