Τρόπος αυτόματης εξαγωγής πληροφοριών εισερχόμενων μηνυμάτων ηλεκτρονικού ταχυδρομείου σε αρχείο Excel με το Outlook VBA

Πολλοί χρήστες ελπίζουν ότι το Outlook μπορεί να εξάγει αυτόματα τις κύριες πληροφορίες των εισερχόμενων μηνυμάτων ηλεκτρονικού ταχυδρομείου σε ένα αρχείο Excel. Αυτό το άρθρο θα εξετάσει αυτήν την απαίτηση και θα παρουσιάσει μια γρήγορη μέθοδο μέσω του Outlook VBA.

Μερικές φορές, για ορισμένους λόγους, όπως στατιστικά στοιχεία αλληλογραφίας, μπορεί συχνά να χρειάζεται να εξάγετε τα μηνύματα ηλεκτρονικού ταχυδρομείου σε ένα αρχείο Excel. Γενικά, για τα υπάρχοντα μηνύματα ηλεκτρονικού ταχυδρομείου που έχετε λάβει, μπορείτε απλώς να χρησιμοποιήσετε τη λειτουργία "Εισαγωγή και εξαγωγή" για να τα εξαγάγετε στο Excel με μία κίνηση. Ωστόσο, ίσως θέλετε ακόμη και το Outlook να μπορεί να εξάγει αυτόματα τα εισερχόμενα email στο Excel μόλις φτάσουν στο γραμματοκιβώτιό σας. Χωρίς αμφιβολία, δεν υπάρχει τέτοια εγγενής δυνατότητα στο Outlook. Επομένως, πρέπει να χρησιμοποιήσετε άλλες προσεγγίσεις, όπως ένα πρόσθετο τρίτου μέρους ή το Outlook VBA. Εδώ θα σας μάθουμε πώς να το κάνετε αυτόματα με το Outlook VBA. Διαβάστε παρακάτω για να λάβετε τα βήματα και σύμφωνα με τους κωδικούς.

Αυτόματη εξαγωγή πληροφοριών εισερχόμενων μηνυμάτων ηλεκτρονικού ταχυδρομείου σε αρχείο Excel

1. Αρχικά, θα πρέπει να δημιουργήσετε ένα αρχείο Excel.

• Ανοίξτε ένα νέο αρχείο Excel.
• Στη συνέχεια, πρέπει να πληκτρολογήσετε "Όχι". στο κελί A1, «Όνομα αποστολέα» στο κελί B1, «Διεύθυνση email αποστολέα» στο κελί C1 και «Θέμα email» στο κελί D1 και «Ώρα λήψης» στο κελί E1, όπως η παρακάτω εικόνα.
• Τέλος, αποθηκεύστε το στο όνομα και τον επιθυμητό φάκελο.

2. Μετά από αυτό, θα πρέπει να εκκινήσετε το Outlook.
3. Στη συνέχεια, πατήστε τα πλήκτρα "Alt + F11", τα οποία θα σας μεταφέρουν στον επεξεργαστή VBA.
4. Στη συνέχεια, στο αναδυόμενο παράθυρο, θα πρέπει να κάνετε διπλό κλικ στο "ThisOutlookSession" στην αριστερή πλευρά.
5. Στη συνέχεια, στο παράθυρο του έργου ThisOutlookSession, πρέπει να αντιγράψετε και να επικολλήσετε τους ακόλουθους κωδικούς VBA σε αυτό.

Public WithEvents objMails As Outlook.Items

Private Sub Application_Startup()
    Set objMails = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub objMails_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim strColumnB As String
    Dim strColumnC As String
    Dim strColumnD As String
    Dim strColumnE As String

    If Item.Class = olMail Then
       Set objMail = Item
    End If
 
    'Specify the Excel file which you want to auto export the email list
    'You can change it as per your case
    strExcelFile = "E:\Email\Email Statistics.xlsx"
 
    'Get Access to the Excel file
    On Error Resume Next
    Set objExcelApp = GetObject(, "Excel.Application")
    If Error <> 0 Then
       Set objExcelApp = CreateObject("Excel.Application")
    End If
    Set objExcelWorkBook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorkSheet = objExcelWorkBook.Sheets("Sheet1")
 
    'Get the next empty row in the Excel worksheet
    nNextEmptyRow = objExcelWorkSheet.Range("B" & objExcelWorkSheet.Rows.Count).End(xlUp).Row + 1
 
    'Specify the corresponding values in the different columns
    strColumnB = objMail.SenderName
    strColumnC = objMail.SenderEmailAddress
    strColumnD = objMail.Subject
    strColumnE = objMail.ReceivedTime
 
    'Add the vaules into the columns
    objExcelWorkSheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorkSheet.Range("B" & nNextEmptyRow) = strColumnB
    objExcelWorkSheet.Range("C" & nNextEmptyRow) = strColumnC
    objExcelWorkSheet.Range("D" & nNextEmptyRow) = strColumnD
    objExcelWorkSheet.Range("E" & nNextEmptyRow) = strColumnE
 
    'Fit the columns from A to E
    objExcelWorkSheet.Columns("A:E").AutoFit
 
    'Save the changes and close the Excel file
    objExcelWorkBook.Close SaveChanges:=True
End Sub

6. Αργότερα θα πρέπει να υπογράψετε αυτόν τον κωδικό.
7. Στη συνέχεια, restart Outlook για να ενεργοποιήσετε το νέο έργο VBA.
8. Τελικά, από εδώ και στο εξής, όλα τα εισερχόμενα email θα εξάγονται αυτόματα στο προκαθορισμένο αρχείο Excel μόλις μεταφερθούν στο φάκελο Εισερχόμενά σας. Το αρχείο excel θα μοιάζει με την παρακάτω εικόνα:

Αποτρέψτε την επώδυνη καταστροφή δεδομένων PST

Το Outlook έχει κερδίσει πολλά εύσημα λόγω των διαφόρων χαρακτηριστικών του. Ωστόσο, αυτό δεν σημαίνει ότι είναι αλάνθαστο. Μπορεί ακόμα να διακυβευτεί ανά πάσα στιγμή. Για παράδειγμα, εάν κλείνετε συχνά το Outlook σας ακατάλληλα, είναι πολύ πιθανό τα δεδομένα σας PST να τεθούν σε κίνδυνο. Σε αυτή την περίπτωση, αν το επιθυμείτε επισκευή PST δεδομένα, πρέπει να καταφύγετε σε ένα έμπειρο εργαλείο, όπως π.χ DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com