Sådan fastgøres de specifikke objektglas på en PowerPoint Præsentation til din Outlook-e-mail

Hvis du vil udtrække de specifikke dias af en PowerPoint præsentation til en separat ny præsentation og vedhæft den til en Outlook-e-mail, kan du bruge måden, der er delt i denne artikel.

I stedet for at vedhæfte en hel PowerPoint præsentation til en e-mail, hvis du vil vedhæfte de specifikke slides af præsentationen, skal du generelt først kopiere de specifikke slides til en ny præsentation. Det er for besværligt. Derfor viser vi dig her en metode, som kan realisere den på én gang.

Fastgør de specifikke dias af en PowerPoint Præsentation til en e-mail

1. Først skal du åbne den specifikke PowerPoint præsentation.
2. Derefter i PowerPoint programvinduet skal du trykke på "Alt + F11"-tasterne for at få adgang til VBA-editor.
3. Opret derefter et nyt modul i det nye vindue ved at trykke på "Indsæt"> "Modul".
4. Kopier og indsæt derefter følgende VBA-kode i dette modul.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Derefter kan du lukke det aktuelle vindue.
6. Gå senere til “Filer” > “Indstillinger” > “Hurtig adgangsværktøjslinje” for at tilføje den nye makro til værktøjslinjen Hurtig adgang.
7. Endelig kan du prøve denne makro.

• Til at starte med skal du vælge de specifikke slides, som du vil udtrække.
• Klik derefter på makroknappen i værktøjslinjen Hurtig adgang.
• Med det samme dukker der en Outlook-e-mail op, hvori der er en PowerPoint præsentation, der er udtrukket fra kildepræsentationen.

Brug et effektivt gendannelsesværktøj

Som vi alle ved, er Outlook udstyret med et indbygget reparationsværktøj - scanpst. Alligevel kan den simpelthen klare små fejl i Outlook. Hvis det, du bliver konfronteret med, er alvorlig skade, vil det ikke have virkninger. På det tidspunkt har du intet andet valg end at vende tilbage til et andet kraftfuldt og pålideligt reparationsværktøj, f.eks DataNumen Outlook Repair. Med det vil du være i stand til at redde din beskadigede Outlook-fil.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com