Sådan flettes og eksporteres flere vedhæftede filer til Excel-projektmappe hurtigt til én projektmappe i Outlook

Outlook-løsninger September 29, 2025

Når du modtager en e-mail vedhæftet med flere Excel-projektmapper, hvis du vil kontrollere indholdet af alle projektmapper i en enkelt projektmappe, kan du bruge måden i denne artikel. Det eksporterer flere Excel-projektmappevedhæftede filer til én projektmappe.

For at se alle vedhæftede filer i en e-mail i en Excel-projektmappe, skal du først kombinere og eksportere disse vedhæftede filer til en enkelt projektmappe. I stedet for at gøre det manuelt, kan du bruge følgende metode til at opnå det med lethed. Den lærer dig at bruge VBA-kode til at opnå det. For at se, hvordan du bruger VBA, kan du se indlægget "Sådan køres VBA-kode i din Outlook".

Flet og eksportér hurtigt flere vedhæftede filer til Excel-projektmappe til én projektmappe i Outlook

Flet og eksporter flere Excel-projektmappevedhæftede filer til én projektmappe

  1. Til at starte med skal du starte din Outlook-applikation.
  2. Åbn derefter Outlook VBA-editor.
  3. Dernæst skal du i det nye vindue "Microsoft Visual Basic for Applications" aktivere "MS Excel Object Library", som du kan læse mere om i artiklen – "Sådan tilføjer du en objektbiblioteksreference i VBA".
  4. Kopier efterfølgende følgende VBA-kode ind i et projekt eller modul.
Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

VBA-kode - flet og eksporter flere vedhæftede filer til Excel-projektmappe til én projektmappe

  1. Derefter kan du lukke vinduet og tilføje den nye makro til Quick Access Toolbar.
  2. Pitch på kildemailen på maillisten senere.
  3. Hold derefter "Ctrl" nede for at vælge de vedhæftede filer i Excel-projektmappe, som du vil eksportere.
  4. Klik derefter på makroknappen i værktøjslinjen Hurtig adgang.Kør makroknap i værktøjslinjen Hurtig adgang
  5. Når makroen er færdig, vises en ny Excel-projektmappe. Det vil indeholde indholdet af de tidligere valgte Excel-projektmapper.Eksporteret Excel-projektmappe

Fald tilbage på et kraftigere eksternt reparationsværktøj

Når de støder på Outlook-korruption, vil de fleste brugere have en tendens til at bruge værktøj til reparation af indbakke at have et forsøg i første omgang. Det vil dog ikke være megen hjælp i tilfælde af alvorlig skade. På det tidspunkt har du intet andet valg end at tage hjælp af et eksternt pålideligt og erfarent værktøj, som f.eks DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder mdf opsving og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.