Sådan udtrækkes hurtigt alle modtagere fra flere Outlook-meddelelsesfiler (.msg)

Nogle brugere vil hurtigt udtrække alle modtagere fra flere Outlook-meddelelsesfiler, der er gemt fra Outlook-e-mails. Nu, denne sost vil se på dette for at dele en hurtig tilgang.

For at udtrække modtagerne fra en enkelt Outlook-meddelelsesfil kan du bare dobbeltklikke for at åbne den og derefter kopiere modtagerne i det åbnede meddelelsesvindue. Men hvis du har brug for at håndtere en række Outlook-meddelelsesfiler, er den manuelle metode ikke effektiv nok. Således kan du se efter en meget mere effektiv måde. Her vil vi introducere en sådan for dig. Læs videre for at få detaljer.

Uddrag alle modtagere fra flere Outlook-meddelelsesfiler (.msg)

1. For somtart, få adgang til Outlook VBA-editor i henhold til “Sådan køres VBA-kode i din Outlook".
2. Kopier derefter og indsæt følgende VBA-kode i et tomt modul.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Flyt derefter markøren i den første underrutine.
4. Klik derefter på knappen "Kør" eller tryk på "F5" -tasten.
5. Derefter skal du i popup-dialogboksen vælge den Windows-mappe, der indeholder kilden Outlook-meddelelsesfiler (.msg).
6. Når du har valgt, skal du klikke på “OK” for at lade makroen fortsætte.
7. Når makroen er færdig, vises en meddelelse, der viser alle udpakkede modtagers e-mail-adresser, som vist i det følgende skærmbillede.

Beskyt dine Outlook-data mod fare

Outlook-data er ganske vist tilbøjelige til korruption. Derfor er det en ganske besværlig opgave at beskytte Outlook-data. Det kræver, at du fortsætter med at lave regelmæssig sikkerhedskopiering af Outlook-data. Hvis det er muligt, er det også klogt og anbefales at udarbejde en erfaren og professionel Outlook PST-reparation værktøj, ligesom DataNumen Outlook Repair, så du kan få øjeblikkelig og rettidig redning i tilfælde af Outlook-korruption.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder genvinde Sql Server og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com