Sådan batches Fjern vedhæftede filer fra forældede kalenderelementer i din Outlook

Hvis du ønsker at fjerne vedhæftede filer fra forældede aftaler og møder i din Outlook, kan du læse denne artikel. Her vil vi introducere dig, hvordan du kan realisere det på én gang.

For at reducere størrelsen på din Outlook-fil anbefales det at rydde op i gamle emner. Dette kan realiseres ved hjælp af den indbyggede “AutoArchive” -funktion, som automatisk kan slette de gamle emner med jævne mellemrum. Imidlertid ønsker nogle brugere bare at slette vedhæftede filer i de gamle varer uden at påvirke elementerne selv. I det følgende lærer vi dig at fjerne vedhæftede filer fra gamle kalenderelementer.

Batch Fjern vedhæftede filer fra forældede kalenderelementer

1. Til at begynde med skal du åbne Outlook VBA-editoren ved hjælp af "Alt + F11".
2. Kopiér derefter VBA-koden i et modul i vinduet “Microsoft Visual Basic for Applications”.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Klik derefter i makroen “BatchDeleteAttachmentsOfOldCalendarItems”.
4. I sidste ende skal du trykke på “F5” -tasten for at køre denne makro.
5. Når makroen er færdig, kan du kontrollere alle dine Outlook-kalendere.
6. Outlook skal have slettet alle vedhæftede filer i de kalenderelementer, der er mere end 2 måneder gamle.

Håndter korrupte Outlook-filer

Har du nogensinde stødt på korruption i Outlook? Hvordan bortskaffer du det normalt? Oftere end ikke ville du først prøve værktøjet til reparation af indbakken - scanpst. Men i tilfælde af alvorlige PST-skader kan det indbyggede værktøj ikke hjælpe dig. Således foreslås det at opbevare et mere erfaren og bemærkelsesværdigt tredjepartsværktøj i nærheden, såsom DataNumen Outlook Repair.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql reparation og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com