6 måder at opbevare de originale vedhæftede filer på e-mail, når du svarer i Outlook

Outlook-løsninger September 29, 2025

Mange brugere håber at konfigurere deres Outlook til at beholde de originale vedhæftede filer, når de besvarer en e-mail. Denne artikel vil afsløre 5 løsninger såvel som en smart måde, der bruger VBA til at realisere det automatisk.

Jeg har hørt et stort antal brugere, der klager over, at Outlook ikke har en oprindelig funktion til at gemme originale vedhæftede filer, når de besvarer en e-mail. Derfor deler vi dig her 6 metoder, hvoraf den ene er ret nyttig, da den bruger VBA til at få Outlook til automatisk at vedhæfte de originale vedhæftede filer til den svarende e-mail. Læs nu for at få dem i detaljer.

Gem de originale vedhæftede filer, når du svarer i Outlook

1. Svar med original email vedhæftet

Selvom Outlook ikke giver en funktion til opretholdelse af originale vedhæftede filer, når de besvarer en e-mail, tillader det brugere at holde original e-mail vedhæftet. Derfor er det en valgfri løsning for dig. Du kan gå til afsnittet "Filer"> "Indstillinger"> "Mail"> "Svar og videresend" for at ændre svarindstillingerne. For flere detaljer anbefales det, at du henviser til min tidligere artikel - “5 trin til at svare med originale vedhæftede filer i Outlook”. Men hvis du stadig håber kun at beholde originale vedhæftede filer, skal du gå videre og lære de andre midler.

2. Træk og slip vedhæftede filer manuelt

  1. Til at begynde med skal du dobbeltklikke på en sådan kilde-e-mail for at åbne den i sit eget vindue.
  2. Klik derefter på "Svar" -knappen, som viser svarende e-mail.
  3. Dernæst skal du krympe begge de to meddelelsesvinduer, indtil du kan se dem på samme skærm.
  4. Vælg derefter alle vedhæftede filer i den originale e-mail.
  5. Til sidst skal du trække og slippe dem til linjen "Vedhæftet" i den svarende e-mail.Træk og slip vedhæftede filer manuelt

3. Kopier & indsæt vedhæftede filer manuelt

  1. For det første skal du vælge alle vedhæftede filer efter åbning af kilde-e-mailen.
  2. Klik derefter på knappen "Kopier" under fanen "Vedhæftede filer".Kopier alle vedhæftede filer
  3. Klik derefter på knappen "Svar" under fanen "Besked" for at åbne en besvarende mail.
  4. I sidste ende, i den svarende e-mail, skal du klikke på linjen "Vedhæftet" og trykke på "Ctrl + V" -knappen for at indsætte de tidligere kopierede vedhæftede filer.

4. Videresend e-mail & udfyld modtager

  1. Vælg først en sådan e-mail, og klik derefter på knappen "Videresend" i båndet.
  2. I det ny popup-meddelelsesvindue opbevares de originale vedhæftede filer. Nu skal du udfylde feltet "Til" til afsenderen af ​​den originale e-mail.
  3. Eventuelt kan du ændre emnet efter dine behov.

5. Send denne e-mail igen, og skift modtagere

  1. Til at begynde med skal du åbne kilde-e-mailen.
  2. Klik derefter på knappen "Handlinger" i gruppen "Flyt".
  3. Vælg derefter "Send denne meddelelse igen" fra rullelisten.
  4. Måske får du en advarsel om, at du ikke er den oprindelige afsender. Bare ignorere det og tryk "Ja".
  5. I den efterfølgende nye e-mail skal du ændre feltet "Til" til afsenderen af ​​den oprindelige e-mail.
  6. Husk også at ændre send ved hjælp af e-mail-konto til din egen konto.

6. Tilføj automatisk originale vedhæftede filer via VBA

Alle de ovennævnte tilgange, for at være ærlige, er løsninger. Hvis du håber, at Outlook automatisk kan gemme originale vedhæftede filer, når du svarer, kan du bruge denne måde.

  1. I hovedvinduet i Outlook skal du trykke på “Alt + F11” -tasterne.
  2. Kopier derefter VBA-koden nedenfor i vinduet “Microsoft Visual Basic for Applications” til projektet “ThisOutlookSession”.
Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

VBA-kode - Gem de originale vedhæftede filer, når du svarer

  1. Senere skal du underskrive denne makro og ændre dine Outlook-makroindstillinger for at tillade de underskrevne makroer.
  2. Genstart derefter dit Outlook-program for at aktivere dette VBA-projekt.
  3. Fra nu af, hver gang du klikker på "Svar" -knappen. Den svarende e-mail vises med originale vedhæftede filer på én gang.

Brug et fremtrædende reparationsværktøj

Outlook har overgået andre e-mail-klienter på grund af dets utallige funktioner. Men det er stadig udsat for korruption. Derfor bør du være mere opmærksom på dets helbred. Generelt, når du støder på små problemer, kan du blot vende tilbage til det indbyggede fix-værktøj. Ikke desto mindre, hvis du lider af alvorlige problemer, skulle du bedre vende tilbage til et meget mere dygtigt værktøj, såsom DataNumen Outlook Repair. Det kan rette Outlook fil på et øjeblik.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder sql rettelse og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com

Kommentarer er lukket.