3 måder at få ordoptællingsstatistikker relateret til tekstfelter, fodnoter og slutnoter i dit dokument

I dagens artikel er der 3 hurtige måder at få ordtællingsstatistikker relateret til tekstfelter, fodnoter og slutnoter i dit dokument.

Det er ikke svært at få det samlede antal ord i et dokument. Men hvis du ønsker at få antallet af ord fra forskellige slags tekster, kræves der flere handlinger. Følgende er 3 metoder. Læs videre for at se, hvad du kan bruge. 

Metode 1: Tæl ord, der inkluderer tekster fra tekstbokse, fodnoter og slutnoter

Som standard tæller Word alle ord, der vises på dokumentet, inklusive tekster i tekstfelter og ord fra fodnoter og slutnoter.

1. Første og foremost, gå til statuslinjen og klik på "Ord" for at åbne boksen "Antal ord".
2. Der vil du se alle slags statistikker. Sørg for at du har markeret afkrydsningsfeltet "Inkluder tekstbokse, fodnoter og slutnoter".
3. Klik derefter på "Luk".
4. Hvis du ikke kan finde kommandoen “Ord” på statuslinjen, skal du højreklikke der.
5. Tjek derefter "Word Count".

Metode 2: Ekskluder tekster fra tekstfelter, fodnoter og slutnoter fra antal ord

Dette er modsat metode 1. Så du skal bare fjerne markeringen i afkrydsningsfeltet "Inkluder tekstbokse, fodnoter og slutnoter".

Metode 3: Kør Word Macro for at få et separat antal ord fra tekstfelter, fodnoter og slutnoter

1. Først skal du udløse "Word Count" -boksen ved hjælp af måde i metode 1 og sikre dig, at valgfeltet er markeret.
2. Tryk derefter på “Alt + F11” for at åbne VBA-editor.
3. Indsæt derefter et nyt modul i “Normal” -projektet ved først at klikke på “Normal”.
4. Og klik på "Indsæt" næste.
5. Vælg derefter “Module”.
6. Dobbeltklik på modulet for at åbne kodningsområdet og indsæt følgende koder der:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Til sidst skal du klikke på “Kør” -knappen.

Hvis der ikke er nogen tekstboks, fodnote eller slutnote, modtager du en meddelelsesboks som denne:

Klik på “OK” for at fortsætte. Derefter vil du se et andet felt, der viser alle detaljer om antal ord.

Få et gendannelsesværktøj

Da Word pludselig kan kollapse, anbefales det at skaffe et avanceret reparationsprodukt til at udføre reparationsjobbet. Et sådant værktøj kan være en god opsparing til korrupte Word. Grib derfor tid på at få en hurtigst muligt.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder rette xls og pdf produkter til reparation af software. For mere information besøg www.datanumen.com