I denne artikel vil vi fokusere på at give dig 3 makroer, som du kan bruge til hurtigt at konvertere Word-dokumenter til pdf filer.
I Word 2003 er der et ikon på menulinjen. Med et enkelt klik er brugere i stand til at udløse "Gem som" vinduet med det samme og gemme dokumentet i pdf format.
Men som du bemærker, ændres layoutet i Word 2010 meget. Og brugere skal klikke på fanen "Filer" og derefter på kommandoen "Gem som" for at udløse vinduet "Gem som". Desuden skal du manuelt vælge gemmetypen, før du trykker på knappen "Gem".
Med alle disse klik er det ikke hurtigt nok. Derfor vil vi i dette indlæg gerne vise den makromæssige måde at gøre det på.
Makro 1: Udløs "Gem som" vinduet hurtigt
- Først og fremmest skal du klikke på fanen "Udvikler" og derefter på kommandoen "Visual Basic" for at åbne VBA-editoren. De to klik skal naturligvis udføres, når fanen "Udvikler" allerede vises. Alternativt kan du trykke på "Alt+F11".
- For det andet skal du klikke på "Normal" projekt.
- For det tredje skal du klikke på "Indsæt" og derefter vælge "Modul" på listemenuen.
- Dobbeltklik nu på modulet for at vise redigeringsområdet.
- Indsæt derefter følgende koder:
Sub TriggerSaveAsWindow()
Dim dlgSaveAs As Dialog
Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
With dlgSaveAs
.Format = wdFormatPDF
.Show
.Execute
End With
End Sub
- Klik derefter på "Kør".
Nu er vinduet "Gem som" åbent. Og gemningstypen er allerede i pdf-format. Alt, hvad du skal gøre, er at klikke på knappen "Gem". Denne makro giver dig mulighed for at ændre filnavnet, hvis det er nødvendigt.
Makro 2: Gem Word-filer direkte til PDF
I tilfælde af at nogle mennesker ønsker at gemme filen direkte til pdf uden at ændre filnavnet, her er makroen, der er brug for.
- Gentag først de første 4 trin ovenfor.
- Indsæt derefter følgende koder i stedet:
'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
Dim objDoc As Document
Set objDoc = ActiveDocument
objDoc.ExportAsFixedFormat _
OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub
- På samme måde skal du klikke på "Kør".
Makro 3: Batchkonvertering af Word Docx-filer til PDF'er
- Placer alle docx-filer i én mappe først.
- Følg ovenstående trin for at have redigeringsområdet åbent.
- Indsæt derefter følgende makro:
Sub BatchConvertDocxToPDF()
Dim objDoc As Document
Dim strFile As String, strFolder As String
'Initialization
strFolder = "C:\Users\Test\Desktop\Test Files\"
strFile = Dir(strFolder & "*.docx", vbNormal)
'Precess each file in the file folder and convert them to pdf.
While strFile <> ""
Set objDoc = Documents.Open(FileName:=strFolder & strFile)
objDoc.ExportAsFixedFormat _
OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
Range:=wdExportAllDocument, Item:=wdExportDocumentContent
objDoc.Close
strFile = Dir()
Wend
End Sub
- Glem aldrig at klikke på "Kør"-knappen.
Bemærk: I koder "strFolder = "C:\Users\Test\Desktop\Test Files\"", det ""C:\Users\Test\Desktop\Test Files\"" er filstien til mappen. Husk at ændre det i overensstemmelse hermed.
Efter at have kørt denne makro, gemmes PDF-filer i den samme mappe, hvor Word-dokumenter opbevares.
Sikre filer som du kan
Der findes forebyggende foranstaltninger og handlinger efter katastrofer for at redde beskadigede filer. Hvis du fortsætter med at sikkerhedskopiere dine filer regelmæssigt, er det nemt at gendanne den originale fil. Sandheden er, at få mennesker kan holde sig til deres sikkerhedskopieringsplan, hvilket øger risikoen for at miste værdifulde data. Under sådanne omstændigheder er det tid til at ty til en avanceret sikkerhedskopiering. Værktøj til reparation af korruption af Word-dokument.
Forfatter Introduktion:
Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget Excel xlsx rettelse og pdf produkter til reparation af software. For mere information besøg www.datanumen.com



