3 hurtige måder at slette tomme rækker og kolonner i din Word-tabel

I dette indlæg vil vi forklare dig 3 hurtige måder at slette tomme rækker og kolonner i din Word-tabel.

Tabeller er essentielle for et dokument, især i forhold til at opbevare forskellige typer data. Nogle gange kan en lang tabel overstige en side og strække sig over flere. Så når først et bord bliver langt og kompliceret, er der foranstaltninger, du kan gøre for at forenkle det. For eksempel kan du slette unødvendige tomme rækker og kolonner.

Følgende er 3 metoder, du kan bruge.

Metode 1: Slet tomme rækker og kolonner manuelt

1. Først skal du vælge en række eller en kolonne i tom tilstand.
2. Højreklik derefter for at få den kontekstuelle menu. I menuen skal du vælge "Slet rækker" eller "Slet kolonner" i overensstemmelse hermed.

Desværre kan du ikke markere flere ikke-på hinanden følgende rækker eller kolonner og slette dem sammen på denne måde. For denne efterspørgsel kan du henvise til vores tidligere artikel: 5 hurtige metoder til batch-sletning af flere rækker eller kolonner i din ordtabel

Metode 2: Batch slet alle tomme rækker og kolonner i en tabel

Metode 1 har sin begrænsning. Så vi vil tilbyde dig måden at batchfjerne rækker og kolonner i en tabel via VBA-koder.

1. Til at begynde med skal du placere markøren inde i en måltabel.
2. For det andet, udløs VBA-editor ved at trykke på "Alt+ F11".
3. I editoren skal du først klikke på "Normalt" projekt.
4. Klik derefter på fanen "Indsæt" i menulinjen.
5. I rullemenuen skal du vælge “Modul”.
6. Dobbeltklik på modulet for at åbne det og indsæt følgende koder der:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Til sidst skal du klikke på knappen "Kør" på menulinjen eller trykke på "F5".

På få sekunder vil du få fjernet alle tomme rækker og kolonner i den tabel.

Metode 3: Batch-slet alle tomme rækker og kolonner i alle tabeller i et dokument

1. Gentag først trin i metode 2 for at installere og køre en makro.
2. Kun denne gang skal du erstatte denne makro med følgende:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Gendan ødelagt dokument

Der er mere end bare én måde at gendanne tabte data på i dag. For eksempel er det altid din højeste prioritet at ty til sikkerhedskopier. Hvis det ikke tilfredsstiller dit behov for at få de seneste oplysninger tilbage, kan du prøve en doc reparation værktøj.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder xlsx reparation og pdf produkter til reparation af software. For mere information besøg www.datanumen.com