2 måder til hurtigt at flette flere orddokumenter til en via VBA

I denne artikel er vi glade for at dele med dig 2 måder til hurtigt at flette flere Word-dokumenter til et via VBA.

I Word er der den indbyggede standardfunktion, der hjælper brugeren med at kombinere eller flette flere dokumenter til et. Detaljer forklares i denne artikel: Sådan kombineres og flettes flere Word-dokumenter til en

Med denne metode skal du foretage et par klik, og indholdet af det næste dokument kommer altid lige efter det forrige. Derfor vil vi tilbyde dig hurtigere måder at gøre det på.

Metode 1: Flet valgte dokumenter til en

1. Først og fremmest skal du oprette et nyt, tomt dokument.
2. Trigger VBA-editor i Word ved at trykke på “Alt + F11”.
3. Klik derefter på “Normal”.
4. Klik derefter på "Indsæt".
5. Og vælg “Module”.
6. Dobbeltklik på nyt modul for at åbne redigeringsområdet.
7. Indsæt følgende makro der:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Klik derefter på "Kør" eller tryk på "F5".
9. Nu i vinduet "Gennemse" skal du vælge flere filer ved at trykke på "Ctrl" og klikke på "OK".
10. Derefter vil alt indhold i de valgte filer blive samlet i det nye dokument, hvor teksten fra hvert dokument starter på en ny side.

Bemærk:

Som vi nævnte, sætter denne makro tekster fra hvert dokument på en ny side. Men hvis du har brug for dem efter hinanden, kan du ændre nogle kodelinjer i makroen. Find bare linjen "Hvis nEachSelectedFile <nTotalFiles derefter", slet den og de næste seks linjer også.

Metode 2: Flet alle dokumenter i en mappe til en

Hvis du har en mappe med filer, der skal kombineres, skal denne makro fungere smukt.

1. For at starte skal du installere og køre makroen som beskrevet i metode 1.
2. Udskift derefter makro med denne:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Kør makroen ved at klikke på "Kør".
4. Derefter vises vinduet "Gennemse" åbent. Vælg den mappe, hvor du gemmer alle dokumenter. Og klik på “OK”.

På samme måde starter teksten i hvert dokument på en ny side. For at få dem til at hænge sammen efter hinanden, skal du finde og slette kodelinjen “.InsertBreak Type:=wdPageBreak”.

Beskyt dit Word-dokument korrekt

En af de bedste måder at beskytte dine Word-dokumenter på er at sikkerhedskopiere dem regelmæssigt. Med sikkerhedskopier i hånden behøver du aldrig være bange for tab af data. Desuden anbefales det også at få et værktøj til reparation docx hvis nogen af ​​dem bliver beskadiget.

Forfatter Introduktion:

Vera Chen er en datagendannelsesekspert i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder beskadiget Excel og pdf produkter til reparation af software. For mere information besøg www.datanumen.com