2 hurtige måder at eksportere listen over alle markerede Outlook-e-mails til Excel

Hvis du vil eksportere listen over alle markerede e-mails fra din Outlook-postkasse til Excel, kan du bruge en af ​​de to metoder, der deles i denne artikel.

For eksempel for at håndtere alle markerede e-mails mere rettidigt eller dele dem med en anden, kan du måske håbe at eksportere dem til et Excel-regneark. Her introducerer vi to tilgange til at realisere det. Den tidligere bruger standardfunktionen "Import og eksport" efter at have fundet markerede e-mails. For at være ærlig er det lidt kedeligt. Således i den sidstnævnte lærer vi dig en mere bekvem måde, der anvender VBA.

Metode 1: Eksportér alle fundne markerede e-mails manuelt

1. Klik først i søgefeltet over postlisten.
2. Klik derefter på "Alle postvarer" i gruppen "Omfang" under fanen "Søg".
3. Klik derefter på knappen "Flagget" i gruppen "Definer".
4. Efter alle markerede e-mails vist på listen skal du vælge en mail og trykke på "Ctrl + A" for at vælge dem alle.
5. Tryk derefter på "Ctrl + Skift + V" -tastgenveje.
6. I den nye dialogboks skal du oprette en ny mappe under Outlook-filen.
7. Senere skal du vælge den nyoprettede mappe og klikke på “OK”, som flytter alle fundne markerede e-mails til den nye mappe.
8. Klik derefter på "File"> "Open"> "Import",
9. I popup-dialogboksen skal du vælge "Eksporter til en fil"> "Næste"> "Microsoft Excel 97-2003"> "Næste".
10. På den nye skærm skal du vælge den korrekte mappe og trykke på "Næste".
11. Følg derefter guiderne for at gennemføre “Eksport”.
12. Du får en ny Excel-fil, vist som følgende skærmbillede.

Metode 2: Eksportér listen over alle markerede e-mails via VBA

1. I Outlook skal du trykke på “Alt + F11” for at udløse VBA-editor.
2. Aktiver derefter “MS Excel Object” i overensstemmelse med “Sådan tilføjer du en objektbiblioteksreference i VBA".
3. Kopier derefter VBA-koden nedenfor til et modul.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Til sidst skal du placere markøren i "ExportAllFlaggedEmailsToExcel" underrutinen og trykke på "F5" -tasten.
5. Vælg derefter en Outlook-fil i den nye dialogboks.
6. Når du får meddelelsen "Afsluttet", får du også en ny Excel-fil, som billedet nedenfor.

Beskyt din Outlook mod korruption

Outlook er tilbøjeligt til fejl og korruption, og derfor er det en meget vanskelig opgave for os at beskytte vores Outlook-data. Den mest effektive og praktiske måde er uden tvivl at lave regelmæssige sikkerhedskopier af data til Outlook. Derudover er det også nødvendigt for os at få fat i et kraftfuldt og pålideligt Outlook-reparationsværktøj, f.eks. DataNumen Outlook Repair. Det vil være nyttigt, hvis værktøj til reparation af indbakke har ingen virkning.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder fastsætte SQL Server og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com