2 Metoder til hurtigt at sende valgte celler i et Excel-regneark som en Outlook-e-mail

Til tider vil du måske hurtigt indsætte de valgte celler i et Excel-regneark til en Outlook-e-mail og sende denne e-mail. Denne artikel vil se på dette ønske om at tilbyde dig to metoder.

Min tidligere artikel “2 hurtige metoder til at sende et Excel-regneark som en Outlook-e-mail”Har lært dig, hvordan du sender et helt Excel-regneark som en e-mail. Nogle gange vil du dog kun sende de valgte celler i et regneark som en e-mail. Som svar på dette krav vil vi her udsætte dig for to metoder. Du kan vælge enten efter dine præferencer.

Metode 1: Kopier valgte celler til e-mail manuelt

1. Til at starte med skal du åbne kildefilen i Excel og få adgang til det rigtige Excel-regneark.
2. Vælg derefter de celler, som du vil sende som en Outlook-e-mail.
3. Tryk derefter på "Ctrl + C" -tastgenveje for at kopiere de valgte celler.
4. Start derefter din Outlook-applikation.
5. Klik derefter på knappen "Ny e-mail" i båndet "Hjem" for at oprette en ny Outlook-e-mail.
6. Senere i det nye meddelelsesvindue skal du klikke på sektionen for meddelelsens brødtekst.
7. Og tryk derefter på "Ctrl + V" -tasten for at indsætte de tidligere kopierede valgte Excel-celler.
8. Endelig kan du komponere e-mailen som sædvanlig og klikke på "Send" -knappen for at sende den ud.

Metode 2: Send valgte celler som e-mail via VBA

1. Åbn kilden Excel-projektmappe lige fra starten.
2. Tryk derefter på “Alt + F11” -tasten for at få adgang til Excel VBA-editor.
3. I det nye vindue skal du klikke på "Indsæt"> "Modul" for at indsætte et nyt modul.
4. Dernæst skal du aktivere Microsoft Outlook Object. Klik på "Værktøjer" > "Referencer". Find og marker "Microsoft Outlook Object Library" i pop op-dialogboksen.
5. Kopier derefter følgende VBA-kode til dette modul.

Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

6. Til sidst kan du prøve.

• Vælg først de specifikke celler som normalt.
• Derefter tilbage til den nye makro, og tryk på F5-tasten for at udløse den.
• Straks vises en ny Outlook-e-mail, hvor du kan se, at de valgte celler er blevet indsat i e-mail-kroppen, som følgende skærmbillede:

PST-fil er den samme sårbare som Excel-fil

Som vi ved, er Excel-filer og Word-dokumenter tilbøjelige til at blive beskadiget. Faktisk gælder det samme for PST-filer, som indeholder alle elementer i din Outlook-postkasse. Så det er en vanskelig opgave at sikre dine PST-data. En af de mest effektive foranstaltninger er at sikkerhedskopiere filen regelmæssigt. Derudover, for at kunne tilbyde øjeblikkelig redning, bør du have et erfarent værktøj klar, f.eks. DataNumen Outlook Repair, som er i stand til gendanne Outlook data uden at svede.

Forfatter Introduktion:

Shirley Zhang er ekspert i datagendannelse i DataNumen, Inc., som er verdens førende inden for datagendannelsesteknologier, herunder reparation mdf og Outlook-reparationssoftwareprodukter. For mere information besøg www.datanumen.com