উইন্ডোজ ফোল্ডারে সমস্ত আউটলুক বার্তা ফাইলগুলি থেকে কীভাবে দ্রুত সংযুক্তিগুলি বের করা যায়

এখন শেয়ার:

সম্ভবত আপনি উইন্ডোজ ফোল্ডারে .msg ফর্ম্যাটে একাধিক আউটলুক ইমেলগুলি সঞ্চয় করেছেন। এবং পরে, আপনি এই ফাইলগুলি থেকে সংযুক্তিগুলি বের করতে চান, আপনি এই নিবন্ধে ভাগ করা উপায়টি ব্যবহার করতে পারেন।

আপনার আউটলুকের ইমেলগুলি থেকে সংযুক্তিগুলি উত্তোলন করা বেশ সহজ। তবে উইন্ডোজ ফোল্ডারে .msg ফাইল হিসাবে রফতানি করা ইমেলগুলি সম্পর্কে কী বলা যায়? সাধারণভাবে, আপনাকে প্রথমে আপনার আউটলুকে এই .msg ফাইলগুলি খুলতে হবে এবং তারপরে একে একে সংযুক্তিগুলি সংরক্ষণ করতে হবে। সম্ভবত আপনি এটি খুব জটিল মনে করবেন। সুতরাং, এরপরে, আমরা আপনাকে আরও একটি দ্রুত সমাধান শিখিয়ে দেব।

উইন্ডোজ ফোল্ডারে সমস্ত আউটলুক বার্তা ফাইল থেকে সংযুক্তিগুলি বের করুন

  1. শুরুতে, আপনার Outlook অ্যাপ্লিকেশনটি চালু করুন এবং VBA এডিটরটি চালান।
  2. তারপরে, "অ্যাপ্লিকেশনগুলির জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" উইন্ডোতে, নীচের ভিবিএ কোডটি একটি অব্যবহৃত মডিউলে অনুলিপি করুন।
Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

ভিবিএ কোড - একটি উইন্ডোজ ফোল্ডারে সমস্ত আউটলুক বার্তা ফাইল থেকে সংযুক্তিগুলি বের করুন

  1. এরপরে, কার্সারটিকে প্রথম সাবরুটিনে সরান এবং "F5" কী বোতামটি চাপুন।
  2. এরপরে, আপনাকে পপআপ ডায়ালগ বাক্সে উত্স উইন্ডোজ ফোল্ডারটি চয়ন করতে হবে।উইন্ডোজ ফোল্ডার নির্বাচন করুন
  3. "ওকে" ক্লিক করার পরে, ম্যাক্রো কাজ চালিয়ে যাবে।
  4. এটি শেষ হয়ে গেলে আপনি "সম্পূর্ণ" বার্তাটি পাবেন।
  5. এখন, আপনি উত্তোলিত সংযুক্তিগুলি সংরক্ষণের জন্য পূর্বনির্ধারিত স্থানীয় ফোল্ডারে অ্যাক্সেস পেতে পারেন।সংযুক্তিযুক্ত

আউটলুক সমস্যাগুলি দক্ষতার সাথে নিষ্পত্তি করুন

যেহেতু আউটলুক স্বীকার করে ত্রুটিযুক্ত প্রবণ, তাই আপনাকে আউটলুক অবজেক্টগুলির সাথে ডিল করার সময় সতর্কতা অবলম্বন করতে হবে, যেমন অজানা ইমেলগুলিতে এমবেড করা ফাইল বা লিঙ্কগুলিতে কখনই বিশ্বাস না করা ইত্যাদি। অন্যথায়, আপনার আউটলুক ফাইলটি সহজেই দুর্নীতিগ্রস্থ হতে পারে। এই পরিস্থিতিতে, এমনকি অভ্যন্তরীণ স্থির সরঞ্জামও খুব বেশি সহায়ক হবে না। আপনি যা অবলম্বন করতে পারবেন তা কেবল অভিজ্ঞ বাহ্যিক ইউটিলিটি like DataNumen Outlook Repair। এটা হতে পারে পিএসটি ঠিক করুন অনায়াসে ফাইল সহ ফাইল করুন।

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় দূষিত বর্গ এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com

এখন শেয়ার:

মন্তব্যসমূহ বন্ধ করা হয়.