প্রতিটি রঙ বিভাগে আউটলুক অ্যাপয়েন্টমেন্টগুলিতে কীভাবে দ্রুত মোট সময় ব্যয় করা যায়

আপনি যদি প্রতিটি রঙ বিভাগে অ্যাপয়েন্টমেন্টগুলিতে মোট সময় ব্যয় করেন সে সম্পর্কে একটি প্রতিবেদন তৈরি করতে চান, তবে আপনি এই নিবন্ধে প্রবর্তিত পদ্ধতিটি ব্যবহার করতে পারেন। এটি আপনাকে ম্যানুয়ালি গণনা ছাড়াই দ্রুত সময়ে এটি সফল করতে সহায়তা করতে পারে।

অনেক ব্যবহারকারী তাদের বেশিরভাগ কার্যকলাপ আউটলুক ক্যালেন্ডারে লিখে রাখতে অভ্যস্ত। এছাড়াও, সেগুলোকে আরও সহজে পরিচালনা ও আলাদা করার জন্য, তারা প্রত্যেকটিকে বিভিন্ন ক্যাটাগরিতে ভাগ করে দেন। এক্ষেত্রে, কিছু ব্যবহারকারী প্রতিটি রঙের ক্যাটাগরিতে থাকা ক্যালেন্ডারের আইটেমগুলোতে ব্যয় করা মোট সময় দেখিয়ে একটি রিপোর্ট তৈরি করতে চান। নিঃসন্দেহে, হাতে-কলমে গণনা করে তথ্য প্রবেশ করানো বেশ কষ্টসাধ্য। তাই, এখানে আমরা এমন একটি উপায় শেয়ার করব যার মাধ্যমে একটি মাত্র ক্লিকেই এই কাজটি সম্পন্ন করা যাবে।

প্রতিটি রঙ বিভাগে অ্যাপয়েন্টমেন্টগুলিতে মোট সময় ব্যয় করুন রফতানি করুন

1. প্রথম স্থানে, আপনার আউটলুক অ্যাপ্লিকেশন চালু করুন।
2. তারপরে, আউটলুক উইন্ডোটি প্রবেশ করার পরে, আপনি "Alt + F11" কী বোতামে আলতো চাপতে পারেন।
3. এরপরে, আপনি "অ্যাপ্লিকেশনগুলির জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" উইন্ডোটিতে অ্যাক্সেস পাবেন।
4. এরপরে, আপনাকে “মাইক্রোসফট এক্সেল অবজেক্ট লাইব্রেরি” সক্রিয় করতে হবে। এটি করার জন্য আপনি “টুলস” > “রেফারেন্স”-এ ক্লিক করতে পারেন।
5. তারপরে, আপনার ব্যবহার করা হয়নি এমন একটি মডিউল খুঁজে বের করতে হবে।
6. এর পরে, আপনাকে এই মডিউলে নিম্নলিখিত ভিবিএ কোডটি অনুলিপি করতে হবে।

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. অবশেষে আপনি এই ম্যাক্রোটি ট্রিগার করতে পারেন, টুলবারে "রান" আইকনটি ক্লিক করে বা "F5" কী বোতামটি টিপে কোনও ব্যাপার নয়।
8. তারপরে, আপনাকে একটি নির্দিষ্ট ক্যালেন্ডার নির্বাচন করার অনুরোধ করা হবে।
9. আপনি "ওকে" নির্বাচন করুন এবং টিপুন করার পরে, ম্যাক্রো চলতে থাকবে। এটি শেষ হওয়ার পরে, একটি নতুন এক্সেল ফাইল থাকবে যা পটভূমিতে প্রদর্শিত হবে।
10. আপনি এটি অ্যাক্সেস করতে পারেন। এটি নীচের স্ক্রিনশটের মতো দেখাবে:

আপনার আউটলুকের আশেপাশে সম্ভাব্য হুমকির জন্য নজর রাখুন

আউটলুক ব্যবহারকারীদের অজানা ইমেল সংযুক্তি, এম্বেডড লিঙ্ক এবং মানব ত্রুটি সহ সমস্ত সম্ভাব্য ঝুঁকিগুলি পর্যবেক্ষণ করা উচিত। অন্যথায়, আপনার আউটলুক যে কোনও সময় দূষিত হতে পারে। এছাড়াও, নিয়মিত আউটলুক ডেটা ব্যাকআপ করা এবং বিশেষায়িত মেরামতের সরঞ্জাম রাখা প্রয়োজনীয়তার বিষয়। DataNumen Outlook Repair এটি সবচেয়ে বেশি সুপারিশকৃত মেরামতের সরঞ্জামগুলোর মধ্যে একটি। এটি পারে মেরামত আউটলুক এক মুহুর্তে সমস্যা

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় ক্ষতিগ্রস্থ এমডিএফ এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com