এক্সেল থেকে প্রতিটি আউটলুক ফোল্ডারে আইটেমগুলির মোট গণনা কীভাবে রপ্তানি করা যায়

আপনি যদি প্রতিটি আউটলুক ফোল্ডারে আইটেমের গণনা সম্পর্কে একটি প্রতিবেদন পেতে চান তবে আপনি এই নিবন্ধে প্রবর্তিত পদ্ধতিটি ব্যবহার করতে পারেন। এটি দ্রুত গণনা করে ফলাফলগুলি এক্সেল ফাইলে রফতানি করবে।

আমার আগের লেখায় - "আউটলুক ভিবিএর মাধ্যমে কোনও ফোল্ডার এবং এর সমস্ত সাবফোল্ডারগুলিতে কীভাবে আইটেমগুলির মোট গণনা পাবেন?”, আপনি একটি ফোল্ডারে আইটেমের গণনা পেতে ভিবিএ ব্যবহার করে একটি পদ্ধতি শিখতে পারেন। তবে, এর মাধ্যমে, আপনি যদি সমস্ত ফোল্ডারে আইটেমগুলি গণনা করতে চান, আপনাকে প্রতিটি ফোল্ডার নির্বাচন করতে হবে এবং ম্যাক্রোকে একে একে চালাতে হবে। এটা কিছুটা ক্লান্তিকর। অতএব, আমরা আপনাকে অন্য একটি পদ্ধতি শিখাব, যা একটি এক্সেল ফাইলে গণনা রফতানি করবে।

এক্সেল থেকে প্রতিটি আউটলুক ফোল্ডারে আইটেমের মোট গণনা রফতানি করুন

1. শুরুতে, আপনার আউটলুক প্রোগ্রামটি চালু করুন।
2. তারপরে মূল আউটলুক উইন্ডোতে "Alt + F11" কী বোতাম টিপুন।
3. এরপরে আপনি "অ্যাপ্লিকেশনগুলির জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" উইন্ডোতে উঠবেন, এতে আপনাকে ব্যবহার না করা একটি মডিউল খোলার দরকার আছে।
4. পরবর্তীকালে, এই মডিউলটিতে নিম্নলিখিত ভিবিএ কোডটি অনুলিপি করুন এবং আটকান।

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. এর পরে, আপনাকে আপনার আউটলুক ম্যাক্রো সুরক্ষা স্তরটিকে নিম্নে পরিবর্তন করতে হবে।
6. তারপরে আপনি নতুন যুক্ত হওয়া ম্যাক্রোতে ফিরে যেতে পারেন এবং এই ম্যাক্রোটি চালাতে F5 কী বোতামটি টিপতে পারেন।
7. এর পরে আপনাকে একটি উত্স PST ফাইল নির্বাচন করতে হবে এবং "ওকে" চাপুন।
8. ম্যাক্রো শেষ হওয়ার পরে আপনি নতুন এক্সেল ফাইলটি খুঁজতে পূর্বনির্ধারিত স্থানীয় ফোল্ডারে যেতে পারেন, যা নিম্নলিখিত স্ক্রিনশটের মতো দেখাবে:

বিরক্তিকর পিএসটি ত্রুটিগুলি স্থির করুন

আউটলুক ব্যবহারের সময় আপনি হয়ত বিভিন্ন সমস্যা সমাধান করেছেন। ছোট সমস্যাগুলি মোকাবেলা করতে আপনি কেবল এটিকে অবলম্বন করতে পারেন ইনবক্স মেরামতের সরঞ্জাম। তবুও, যদি সমস্যাগুলি এত মারাত্মক হয় যে তারা ইনবিল্ট সরঞ্জাম যা করতে পারে তার বাইরে চলে যায়, আপনাকে আরও শক্তিশালী সরঞ্জাম ব্যবহার করতে হবে, যেমন DataNumen Outlook Repair.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় এমডিএফ মেরামত এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com