আপনি যদি কোনও এক্সল ওয়ার্কশিটে আউটলুক ইমেলের সমস্ত চিত্র সংযুক্তি দ্রুত রফতানি করতে চান তবে আপনি এই নিবন্ধটি উল্লেখ করতে পারেন। এখানে আমরা আপনাকে ম্যানুয়ালি রফতানির চেয়ে আরও কার্যকর উপায় দেখাব।
যখন আপনি এমন কোনো ইমেল পান যাতে অনেকগুলো ছবি অ্যাটাচমেন্ট হিসেবে থাকে, এবং আপনি যদি সেগুলো ব্যবহার করে এক্সেলে একটি রিপোর্ট তৈরি করতে চান, তাহলে নিশ্চয়ই এমন একটি উপায় খোঁজেন যা দিয়ে এই ছবিগুলোকে একসাথে অনেকগুলো এক্সেল ওয়ার্কশিটে এক্সপোর্ট করা যায়। এখন, আমরা নিচে আপনাকে ঠিক এমনই একটি পদ্ধতির সাথে পরিচয় করিয়ে দেব।
কোনও এক্সেল ওয়ার্কশিটে ইমেলের সমস্ত চিত্র সংযুক্তি রফতানি করুন
- শুরু করার জন্য, আপনার আউটলুক অ্যাপ্লিকেশনটিকে সাধারণ ফ্যাশনে অ্যাক্সেস করুন।
- তারপরে, আউটলুক উইন্ডোতে, "Alt + F11" কী শর্টকাটগুলি টিপুন, যা "অ্যাপ্লিকেশনগুলির জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" আনবে।
- এই স্ক্রিনে আপনাকে একটি মডিউল খোলার প্রয়োজন যা ব্যবহার হচ্ছে না বা সরাসরি একটি নতুন sertোকাতে হবে।
- এর পরে, আপনাকে এই মডিউলে নীচে ভিবিএ কোডের টুকরো অনুলিপি করা উচিত।
Sub ExportAllImageAttachmentsToExcelWorksheet()
Dim objSourceMail As Outlook.MailItem
Dim objAttachment As Outlook.Attachment
Dim strImage As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim objFile As Object
Dim objFiles As Object
Dim nRow As Integer
Select Case Outlook.Application.ActiveWindow.Class
Case olInspector
Set objSourceMail = ActiveInspector.currentItem
Case olExplorer
Set objSourceMail = ActiveExplorer.Selection.Item(1)
End Select
If Not (objSourceMail Is Nothing) Then
'Save the image attachments to a temporary folder
strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
MkDir (strTempFolder)
Set objFileSystem = CreateObject("Scripting.FileSystemObject")
For Each objAttachment In objSourceMail.Attachments
If IsEmbedded(objAttachment) = False Then
Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
Case "jpg", "jpeg", "png", "bmp", "gif"
objAttachment.SaveAsFile strTempFolder & objAttachment.filename
End Select
End If
Next
'Create a new Excel workbook
Set objExcelApp = CreateObject("Excel.Application")
Set objExcelWorkbook = objExcelApp.Workbooks.Add
Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
objExcelApp.Visible = True
objExcelWorkbook.Activate
'Get the images in the temporary folder
Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
'Insert the images into this new Excel worksheet
For Each objFile In objFiles
strImage = strTempFolder & Trim(objFile.Name)
nRow = nRow + 1
With objExcelWorksheet
.Range("A" & nRow).value = objFile.Name
'Change the height and width as per your needs
.Range("B" & nRow).ColumnWidth = 10
.Range("B" & nRow).RowHeight = 80
.Range("B" & nRow).Activate
With .Pictures.insert(strImage)
With .ShapeRange
.LockAspectRatio = msoTrue
.Width = 50
.Height = 70
End With
End With
.Columns("A").AutoFit
.Activate
End With
Next
End If
End Sub
Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
Dim objPropertyAccessor As Outlook.propertyAccessor
Dim strProperty As String
Set objPropertyAccessor = objCurAttachment.propertyAccessor
strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
If InStr(1, strProperty, "@") > 0 Then
IsEmbedded = True
Else
IsEmbedded = False
End If
End Function
- এর পরে, আপনি ম্যাক্রো থেকে প্রস্থান করতে পারেন।
- তারপরে, দ্রুত অ্যাক্সেস সরঞ্জামদণ্ডে এই ম্যাক্রো যুক্ত করতে "ফাইল"> "বিকল্পগুলি"> "দ্রুত অ্যাক্সেস সরঞ্জামদণ্ড" এ যান।
- অবশেষে, আপনি এখনই এই ম্যাক্রোটি ব্যবহার করে দেখতে পারেন।
- প্রথমত, নির্বাচন করুন বা কোনও উত্স ইমেল খুলুন।
- তারপরে, কুইক অ্যাক্সেস সরঞ্জামদণ্ডে ম্যাক্রো বোতামটি ক্লিক করুন।
- ম্যাক্রো সম্পূর্ণ হলে, আপনি নিম্নলিখিত স্ক্রিনশটের মতো দেখানো একটি এক্সেল ওয়ার্কশিট পাবেন:
দুর্নীতিগ্রস্থ হওয়া থেকে আউটলুক ফাইলটিকে রক্ষা করুন
এটি পরিচিত যে আউটলুক দুর্নীতির প্রবণ। সুতরাং, আমাদের বুঝতে হবে কীভাবে কীভাবে আউটলুক দুর্নীতি রক্ষা করবে। প্রথমে, ভাইরাস আক্রমণগুলি ব্লক করার জন্য, অ্যান্টিভাইরাস সফ্টওয়্যার ইনস্টল করা এবং অজানা সংযুক্তিটি কখনও ডাউনলোড করা দরকার। তদ্ব্যতীত, আমরা একটি শক্তিশালী মেরামতের সরঞ্জাম, যেমন ধরে রাখা ভাল DataNumen Outlook Repairএটি নিম্নলিখিত ক্ষেত্রে সবচেয়ে কার্যকর প্রতিকার দিতে পারে দৃষ্টিভঙ্গি দুর্নীতি.
লেখকের ভূমিকা:
শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় স্কয়ার পুনরুদ্ধার এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com