আউটলুক ভিবিএর মাধ্যমে নির্দিষ্ট তারিখের ব্যাপ্তিতে সমস্ত ব্যস্ত অ্যাপয়েন্টমেন্টগুলির তালিকা কীভাবে প্রিন্ট করা যায়

এই নিবন্ধটি আপনাকে "ব্যস্ত" হিসাবে দেখানো এবং একটি নির্দিষ্ট তারিখের সীমার মধ্যে নির্ধারিত সমস্ত অ্যাপয়েন্টমেন্টের তালিকা প্রিন্ট করার একটি সহজ পদ্ধতি শেখাবে৷

একটি নির্দিষ্ট তারিখের পরিসরের মধ্যে সমস্ত ব্যস্ত অ্যাপয়েন্টমেন্ট খুঁজে বের করার জন্য সমস্ত ক্যালেন্ডারগুলো একবার দেখে নেওয়া বেশ সহজ। আপনি শুধু সার্চ স্কোপটি “All Calendar Items”-এ সেট করতে পারেন। তারপর, “Show Time As”-এর মান “Busy” এবং নির্দিষ্ট শুরু ও শেষের তারিখের মধ্যে থাকা অ্যাপয়েন্টমেন্টগুলো খুঁজুন। কিন্তু, এইভাবে, খুঁজে পাওয়া অ্যাপয়েন্টমেন্টগুলো প্রিন্ট করার জন্য “File” > “Print”-এ গেলে আপনি দেখতে পাবেন যে সেখানে শুধুমাত্র “Memo Style” উপলব্ধ আছে। এর মানে হলো, আপনি খুঁজে পাওয়া অ্যাপয়েন্টমেন্টগুলো তালিকা আকারে প্রিন্ট করতে পারবেন না। তাই, আপনি যদি এই ধরনের অ্যাপয়েন্টমেন্টের তালিকা প্রিন্ট করতে চান, তাহলে আপনি নিম্নলিখিত পদ্ধতিটি ব্যবহার করতে পারেন।

একটি নির্দিষ্ট তারিখ পরিসরে সমস্ত ব্যস্ত অ্যাপয়েন্টমেন্টের তালিকা প্রিন্ট করুন

1. একেবারে গোড়ার দিকে, "Alt + F11" এর মাধ্যমে আউটলুক ভিবিএ সম্পাদক চালু করুন।
2. তারপর, পপ-আপ “Microsoft Visual Basic for Applications” উইন্ডোতে, “MS Excel Object Library”-এর রেফারেন্সটি নিম্নলিখিত অনুসারে যোগ করুন:VBA-তে কীভাবে একটি অবজেক্ট লাইব্রেরি রেফারেন্স যুক্ত করবেন"।
3. এর পরে, একটি মডিউলে নিম্নলিখিত VBA কোডটি রাখুন।

Dim dStart, dEnd As Date
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub PrintListOfAllBusyAppointments()
    Dim objStore As Store
    Dim objFolder As Folder
 
    dStart = InputBox("Enter the start date:", , Date)
    dEnd = InputBox("Enter the end date:", , Date + 30)
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
 
    With objExcelWorksheet
         .Cells(1, 1) = "Subject"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 2) = "Location"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 3) = "Start"
         .Cells(1, 3).Font.Bold = True
         .Cells(1, 4) = "End"
         .Cells(1, 4).Font.Bold = True
         .Cells(1, 5) = "In Folder"
         .Cells(1, 5).Font.Bold = True
    End With
 
    For Each objStore In Application.Session.Stores
        For Each objFolder In objStore.GetRootFolder.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
 
    objExcelWorksheet.Columns("A:E").AutoFit
    objExcelWorksheet.PrintOut
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

Sub ProcessFolders(ByVal objCurFolder As Folder)
    Dim strFilter As String
    Dim objItems As Outlook.Items
    Dim objRestrictedItems As Outlook.Items
    Dim objAppointment As AppointmentItem
    Dim nLastRow As Integer
    Dim objSubFolder As Folder
 
    Set objItems = objCurFolder.Items
    objItems.IncludeRecurrences = True
    objItems.Sort "[Start]"
 
    'Get the appointments in the specific date range
    strFilter = "[Start] >= " & Chr(34) & dStart & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEnd & " 11:59 PM" & Chr(34)
    Set objRestrictedItems = objItems.Restrict(strFilter)

    For Each objAppointment In objRestrictedItems
        If objAppointment.BusyStatus = olBusy Then
           nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
           With objExcelWorksheet
                .Range("A" & nLastRow) = objAppointment.Subject
                .Range("B" & nLastRow) = objAppointment.Location
                .Range("C" & nLastRow) = objAppointment.Start
                .Range("D" & nLastRow) = objAppointment.End
                .Range("E" & nLastRow) = objCurFolder.FolderPath
           End With
        End If
    Next

    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubFolder In objCurFolder.Folders
           Call ProcessFolders(objSubFolder)
       Next
    End If
End Sub

4. পরে, প্রথম সাবরুটিনে ক্লিক করুন এবং "F5" কী বোতাম টিপুন।
5. এরপরে, অ্যাপয়েন্টমেন্ট অনুসন্ধানের জন্য আপনাকে তারিখ পরিসীমা উল্লেখ করতে হবে।
6. পরবর্তীকালে, ম্যাক্রো চালিয়ে যেতে "ঠিক আছে" এ ক্লিক করুন।
7. অবশেষে, ম্যাক্রো শেষ হলে, সমস্ত ক্যালেন্ডার ফোল্ডারে পূর্বনির্ধারিত তারিখ পরিসরে ব্যস্ত অ্যাপয়েন্টমেন্টের তালিকা প্রিন্ট করা হবে, যেমনটি নীচের স্ক্রিনশটে দেখানো হয়েছে।

বিরক্তিকর আউটলুক দুর্নীতি মোকাবেলা

যদি আপনার আউটলুক সবসময় একটি অনুপযুক্ত উপায়ে বন্ধ থাকে, তাহলে আপনি পরে অনেক সমস্যার সম্মুখীন হতে পারেন। এর মধ্যে আউটলুক ফাইলটি সবচেয়ে খারাপ। আপনি যদি আপনার ডেটা হারাতে না চান তবে আপনাকে একটি PST ফিক্স টুল ব্যবহার করতে হবে, যেমন DataNumen Outlook Repair. এটি থেকে সর্বাধিক ডেটা ফিরে পেতে সক্ষম ক্ষতিগ্রস্থ আউটলুক ফাইল.

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় বর্গফুট ঠিক করা এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com