মাইক্রোসফ্ট অ্যাক্সেস থেকে তথ্য রফতানি করা অবিশ্বাস্যভাবে সহজ - ধরে নেওয়া আপনি কেবলমাত্র একটি একক রফতানি ফাইল উত্পাদন করতে চান। আপনি যখন কোনও প্রশ্ন (বা টেবিল) একাধিক রফতানি ফাইলগুলিতে বিভক্ত করতে চান তখন আপনি কী করবেন? উদাহরণস্বরূপ, আপনার যদি প্রতি মাসে গ্রাহকের লেনদেনের একটি তালিকা রফতানি করতে হয় - প্রতিটি গ্রাহকের নিজস্ব রফতানি ফাইল রয়েছে? এই নিবন্ধটি আপনাকে এখানে সহায়তা করতে পারে। 2, 10, বা এক শতাধিক রফতানি রফতানি করা সামান্য ভিবিএ কোড স্নিপেট চালানোর মতো সহজ হবে এবং কাজটি কয়েক সেকেন্ডে শেষ হবে, কয়েক ঘন্টা ম্যানুয়ালি কাট / পেস্ট করার পরে নয়। তো শুরু করা যাক…
অভিগমন
যেহেতু আমরা এটিকে যতটা সম্ভব নমনীয় এবং ব্যবহারযোগ্য হতে চাই, এই নিবন্ধটির কোডটি স্বাভাবিকের চেয়ে কিছুটা দীর্ঘ হতে চলেছে তবে আপনি কেন শীঘ্রই তা দেখতে পাবেন।
প্রথমত - আসুন আমরা কী অর্জন করতে সক্ষম হতে চাই তা রূপরেখা দিন:
একটি জিজ্ঞাসা দেওয়া, প্রতিটি ক্ষেত্রে একটি নির্দিষ্ট ক্ষেত্রের মান পরিবর্তিত একটি নতুন ফাইল আউটপুট।
চ্যালেঞ্জ
এটি করার জন্য, আমাদের কোয়েরির ফলাফলগুলো ধাপে ধাপে পরীক্ষা করতে হবে এবং বর্তমান সারির প্রাসঙ্গিক ফিল্ডটিকে পূর্ববর্তী সারির মানের সাথে তুলনা করতে হবে – আর যদি সেগুলো ভিন্ন হয়, তবে একটি নতুন ফাইল তৈরি করে সেখানে কোয়েরির ফলাফল আউটপুট করা শুরু করতে হবে।
এটি কি জন্য উপযুক্ত নয়
আমি ইতিমধ্যে উল্লেখ করেছি - আপনি আপনার ডাটাবেসের কিছু অংশ রফতানি করতে চান এমন প্রচুর কারণ রয়েছে তবে এটি ব্যাকআপ / সংরক্ষণাগার উদ্দেশ্যে ব্যবহার করা সেগুলির মধ্যে একটি নয় - অবশ্যই আমি এই পদ্ধতির সাথে নেই এখানে ব্যবহার করে - আপনি যদি একটি থেকে পুনরুদ্ধারের মুখোমুখি হন তবে আপনি শেষ কাজটি করতে চান দূষিত এমডিবি ডাটাবেস কীভাবে একসাথে প্রচুর রফতানি ফিরে যায়!
সমাধান?
একটি কাজ করার অনেক উপায় থাকে, এটি তার মধ্যে একটি মাত্র – তবে আমার মনে হয় এটি বেশ ভালোভাবে কাজ করে। প্রথমে আমরা কোয়েরিটিকে একটি অ্যারেতে পড়ে নেব যাতে কাজ করা সহজ হয়। এরপর আমরা সেই অ্যারেটির মধ্যে লুপ চালিয়ে দেখব যে প্রাসঙ্গিক ফিল্ডে কোনো নতুন ভ্যালু পাওয়া গেছে কি না। যদি এটি নতুন ভ্যালু না হয়, তাহলে আমরা যে ফাইলটিতে লিখছি, সেই ফাইলে পুরো রেকর্ডটি আউটপুট করে দেব; আর যদি নতুন হয়, তাহলে আমরা সেই ফাইলটি বন্ধ করে একটি নতুন ফাইল শুরু করব।
এবং কোড…
Sub DoExport(fieldName As String, queryName As String, filePath As String, Optional delim As Variant = vbTab)
Dim db As Database
Dim objRecordset As ADODB.Recordset
Dim qdf As QueryDef
Dim fldcounter, colno, numcols As Integer
Dim numrows, loopcount As Long
Dim data, fs, fwriter As Variant
Dim fldnames(), headerString As String
'get details of the query we'll be exporting
Set objRecordset = New ADODB.Recordset
Set db = CurrentDb
Set qdf = db.QueryDefs(queryName)
'load the query into a recordset so we can work with it
objRecordset.Open qdf.SQL, CurrentProject.Connection, adOpenDynamic, adLockReadOnly
'load the recordset into an array
data = objRecordset.GetRows
'close the recordset as we're done with it now
objRecordset.Close
'get details of the size of array, and position of the field we're checking for in that array
colno = qdf.Fields(fieldName).OrdinalPosition
numrows = UBound(data, 2)
numcols = UBound(data, 1)
'as we'll need to write out a header for each file - get the field names for that header
'and construct a header string
ReDim fldnames(numcols)
For fldcounter = 0 To qdf.Fields.Count - 1
fldnames(fldcounter) = qdf.Fields(fldcounter).Name
Next
headerString = Join(fldnames, delim)
'prepare the file scripting interface so we can create and write to our file(s)
Set fs = CreateObject("Scripting.FileSystemObject")
'loop through our array and output to the file
For loopcount = 0 To numrows
If loopcount > 0 Then
If data(colno, loopcount) <> data(colno, loopcount - 1) Then
If Not IsEmpty(fwriter) Then fwriter.Close
Set fwriter = fs.createTextfile(filePath & data(colno, loopcount) & ".txt", True)
fwriter.writeline headerString
writetoFile data, queryName, fwriter, loopcount, numcols
Else
writetoFile data, delim, fwriter, loopcount, numcols
End If
Else
Set fwriter = fs.createTextfile(filePath & data(colno, loopcount) & ".txt", True)
fwriter.writeline headerString
writetoFile data, delim, fwriter, loopcount, numcols
End If
Next
'tidy up after ourselves
fwriter.Close
Set fwriter = Nothing
Set objRecordset = Nothing
Set db = Nothing
Set qdf = Nothing
End Sub
'parameters are passed "by reference" to prevent moving potentially large objects around in memory
Sub writetoFile(ByRef data As Variant, ByVal delim As Variant, ByRef fwriter As Variant, ByVal counter As Long, ByVal numcols As Integer)
Dim loopcount As Integer
Dim outstr As String
For loopcount = 0 To numcols
outstr = outstr & data(loopcount, counter)
If loopcount < numcols Then outstr = outstr & delim
Next
fwriter.writeline outstr
End Sub
কোডটি কী করছে - মূল পয়েন্টগুলি
আমি কোডের বেশিরভাগ গুরুত্বপূর্ণ জায়গায় মন্তব্য যোগ করেছি, কিন্তু এখনও দু-একটি বিষয় আছে যা উল্লেখ করার মতো।
প্রথম - আমরা কোডটি দুটি রুটিনে বিভক্ত করেছি। বর্তমান রেকর্ডটি বর্তমানে আমরা যে ফাইলটিতে কাজ করছি সেই একই ফাইলটিতে রচনা করা উচিত কিনা বা এটি একটি নতুন ফাইলে লেখা উচিত কিনা তা প্রথম পরীক্ষা করে। দ্বিতীয় রুটিন পুরো রেকর্ডের বিশদটি ফাইলে আউটপুট করে। কোডের নকলকে হ্রাস করার জন্য এটি এইভাবে করা হয়েছে, অন্যথায় আপনি একই জায়গায় অনেক জায়গায় একই লুপিংয়ের ঘটনা ঘটতে দেখবেন।
দ্বিতীয় - আমি যে ক্যোয়ারির বিরুদ্ধে কাজ করছি তার বিশদ পেতে আমি "ক্যোরি সংজ্ঞা" ব্যবহার করছি - আপনি যদি টেবিলগুলির সাথে এটির সাথে কাজ করার জন্য উপযুক্ত হতে চান তবে আপনি অদলবদলের দিকে তাকান যাতে এটি " পরিবর্তে সারণি সংজ্ঞা ”।
এই বলে যে, আমি বেশ আত্মবিশ্বাসী এটি কোডের একটি বিট যা আপনি আবার উল্লেখ করবেন এবং প্রচুর ব্যবহার করবেন!
লেখকের ভূমিকা:
মিচেল পন্ড একটি তথ্য পুনরুদ্ধার বিশেষজ্ঞ is DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় মেরামত SQL Server উপাত্ত এবং এক্সেল পুনরুদ্ধার সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com