কীভাবে ব্যাচ করবেন নির্দিষ্ট তারিখের ব্যাপ্তিতে নির্ধারিত সমস্ত আউটলুক সভা বাতিল করুন

আউটলুক সমাধান সেপ্টেম্বর 29, 2025

আপনি যদি আপনার আউটলুকের নির্দিষ্ট তারিখের সীমার মধ্যে নির্ধারিত সমস্ত সভা বাতিল করতে চান তবে আপনি এই নিবন্ধে প্রবর্তিত উপায়গুলি ব্যবহার করতে পারেন। এটি আপনাকে ম্যানুয়ালি এই জাতীয় সভা অনুসন্ধান এবং বাতিল করা থেকে বাঁচাতে পারে।

যদি, কিছু কারণে, আপনি ভবিষ্যতের নির্দিষ্ট তারিখের পরিসরে অনুষ্ঠিত সভাগুলিতে সংগঠিত বা অংশ নিতে না পারেন তবে আপনি এই জাতীয় সভাগুলি বাতিল করতে চাইতে পারেন। সাধারণত, আপনাকে প্রথমে সেগুলি সন্ধান করতে হবে এবং তারপরে একে একে একে বাতিল করতে হবে। এটা বেশ ঝামেলা হবে। সুতরাং, নিম্নলিখিতগুলিতে, আমরা আপনাকে অন্য একটি উপায় ভাগ করব, যা আরও বেশি সুবিধাজনক far

ব্যাচ নির্দিষ্ট তারিখের জন্য নির্ধারিত সমস্ত সভা বাতিল করে

একেবারে শুরুতে, আপনার আউটলুক প্রোগ্রামটি চালু করুন।
তারপরে, আউটলুকে আপনাকে "Alt + F11" কী বোতাম টিপতে হবে।
এরপরে, আপনি "অ্যাপ্লিকেশনগুলির জন্য মাইক্রোসফ্ট ভিজ্যুয়াল বেসিক" উইন্ডোতে প্রবেশ করবেন।
এই উইন্ডোতে, আপনার অব্যবহৃত মডিউলটি খুলতে হবে বা একটি নতুন inোকানো উচিত।
পরবর্তী সময়ে, আপনি এই মডিউলে নিম্নলিখিত ভিবিএ কোডটি অনুলিপি করতে পারেন।

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

অবশেষে, আপনি এখনই এই ম্যাক্রোটি চালাতে পারেন run

বর্তমান ম্যাক্রো উইন্ডোতে, "F5" কী বোতামটি টিপুন।
এর পরে, আপনাকে তারিখের সীমা নির্দিষ্ট করতে হবে।
এর পরে, অন্য একটি ডায়ালগ বাক্স প্রদর্শিত হবে, যা আপনাকে উত্স ক্যালেন্ডার ফোল্ডারটি বেছে নেওয়ার এবং "ঠিক আছে" ক্লিক করার দাবি করে।
শেষ অবধি, যখন ম্যাক্রো সমাপ্ত হয়, আপনি দেখতে পাবেন যে নির্দিষ্ট তারিখের পরিসরে সমস্ত সভা বাতিল করা হয়েছে।
"প্রেরিত আইটেমগুলি" ফোল্ডারে আপনি নীচের স্ক্রিনশটের মতো সভাগুলি বাতিল করতে পারেন:

আউটলুক ত্রুটিগুলি ঠিক করুন

আপনি যদি কয়েক দশক ধরে আউটলুক ব্যবহার করেন তবে আপনার অবশ্যই বেশ কয়েকটি ত্রুটি হতে হয়েছিল। ভাগ্যক্রমে আউটলুক একটি অন্তর্নির্মিত মেরামত সরঞ্জাম - স্ক্যানপস্ট দিয়ে আসে। আপনি এটি ব্যবহার করতে পারেন আউটলুক ঠিক করুন ত্রুটি তবুও, যদি এটি ব্যর্থ হয় তবে আপনার শেষ অবলম্বনটি বাইরের ফিক্স সরঞ্জামগুলির মতো DataNumen Outlook Repairএটি আউটলুক ফাইল স্ক্যান করে বেশিরভাগ ত্রুটি ঠিক করতে পারে এবং এমনকি ক্ষতিগ্রস্ত আউটলুক ডেটাও সহজে পুনরুদ্ধার করতে পারে।

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় sql ঠিক করুন এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com