এক্সেল থেকে সমস্ত পতাকাঙ্কিত আউটলুক ইমেলের তালিকা রফতানি করার 2 দ্রুত উপায়

এখন শেয়ার:

আপনি যদি আপনার আউটলুক মেলবক্স থেকে এক্সেল থেকে চিহ্নিত সমস্ত ইমেলগুলির তালিকা রফতানি করতে চান তবে আপনি এই নিবন্ধে ভাগ করা 2 টি পদ্ধতির মধ্যে দুটি ব্যবহার করতে পারেন।

উদাহরণস্বরূপ, যাতে সমস্ত পতাকাঙ্কিত ইমেলগুলি আরও সময় মতো ডিল করতে বা অন্য কারও সাথে ভাগ করে নেওয়ার জন্য, আপনি সেগুলি এক্সেল ওয়ার্কশিটে রফতানি করার আশা করতে পারেন। এটি উপলব্ধি করার জন্য আমরা এখানে 2 টি পদ্ধতির পরিচয় করিয়ে দেব। প্রাক্তনটি পতাকাঙ্কিত ইমেলগুলি সন্ধানের পরে মানক "আমদানি ও রপ্তানি" বৈশিষ্ট্যটি ব্যবহার করে। সত্যি কথা বলতে কি কিছুটা ক্লান্তিকর। সুতরাং, দ্বিতীয়টির মধ্যে, আমরা আপনাকে আরও সুবিধাজনক উপায়ে শিখাব যা ভিবিএ প্রয়োগ করে।

এক্সেল থেকে সমস্ত পতাকাঙ্কিত আউটলুক ইমেলের তালিকা রফতানি করুন

পদ্ধতি 1: সমস্ত পাওয়া পতাকাযুক্ত ইমেল ম্যানুয়ালি রফতানি করুন

  1. সবার আগে, মেল তালিকার উপরে অনুসন্ধান বাক্সে ক্লিক করুন।
  2. তারপরে, "অনুসন্ধান" ট্যাবে "সুযোগ" গ্রুপে "সমস্ত মেল আইটেম" ক্লিক করুন।
  3. এরপরে, "সংজ্ঞায়িত" গোষ্ঠীর "পতাকাঙ্কিত" বোতামটি ক্লিক করুন।পতাকাযুক্ত ইমেলগুলি অনুসন্ধান করুন
  4. সমস্ত পতাকাঙ্কিত ইমেলগুলি তালিকায় প্রদর্শিত হওয়ার পরে একটি মেল নির্বাচন করুন এবং সেগুলি নির্বাচন করতে "Ctrl + A" টিপুন।
  5. তারপরে, "Ctrl + Shift + V" কী শর্টকাটগুলি টিপুন।
  6. নতুন ডায়লগ বাক্সে, আউটলুক ফাইলের অধীনে একটি নতুন ফোল্ডার তৈরি করুন।একটি নতুন ফোল্ডার তৈরি করুন
  7. পরে, নতুন তৈরি ফোল্ডারটি নির্বাচন করুন এবং "ঠিক আছে" ক্লিক করুন, যা পাওয়া যায় এমন সমস্ত পতাকাঙ্কিত ইমেলগুলি নতুন ফোল্ডারে স্থানান্তরিত করে।সমস্ত পতাকাঙ্কিত ইমেলগুলি নতুন ফোল্ডারে সরান
  8. এরপরে, "ফাইল"> "খুলুন"> "আমদানি" এ ক্লিক করুন,
  9. পপআপ ডায়ালগ বাক্সে, "একটি ফাইলের কাছে রফতানি করুন"> "পরবর্তী"> "মাইক্রোসফ্ট এক্সেল 97-2003"> "পরবর্তী" চয়ন করুন।একটি ফাইল রফতানি
  10. নতুন স্ক্রিনে, সঠিক ফোল্ডারটি নির্বাচন করুন এবং "পরবর্তী" টিপুন।থেকে রফতানি করতে ফোল্ডারটি নির্বাচন করুন
  11. পরবর্তীকালে, "এক্সপোর্ট" সম্পূর্ণ করতে উইজার্ডগুলি অনুসরণ করুন।
  12. নিম্নলিখিত স্ক্রিনশট হিসাবে প্রদর্শিত একটি নতুন এক্সেল ফাইল পাবেন।এক্সেল ফাইল রফতানি করা হয়েছে

পদ্ধতি 2: ভিবিএর মাধ্যমে সমস্ত পতাকাযুক্ত ইমেলের তালিকাটি রফতানি করুন

  1. আউটলুকে, ভিবিএ সম্পাদককে ট্রিগার করতে "Alt + F11" টিপুন।
  2. তারপরে, "এমএস এক্সেল অবজেক্ট" সক্ষম করুন "VBA-তে কীভাবে একটি অবজেক্ট লাইব্রেরি রেফারেন্স যুক্ত করবেন"।
  3. এরপরে, নীচে ভিবিএ কোডটি একটি মডিউলে অনুলিপি করুন।
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

ভিবিএ কোড - সমস্ত পতাকাযুক্ত ইমেলের তালিকা রফতানি করুন

  1. শেষ অবধি, "এক্সপোর্টএলফ্ল্যাগডইমেলসটোএক্সেল" সাব্রোটিনে কার্সারটি চাপুন এবং "এফ 5" কী বোতামটি চাপুন।
  2. তারপরে, নতুন ডায়লগ বাক্সে একটি আউটলুক ফাইল নির্বাচন করুন।আউটলুক ফাইল নির্বাচন করুন
  3. আপনি যখন "সম্পূর্ণ" প্রম্পট পাবেন, আপনি নীচের চিত্রের মতো একটি নতুন এক্সেল ফাইলও পাবেন।ভিবিএর মাধ্যমে এক্সেল ফাইল রফতানি করা হয়েছে

আপনার দৃষ্টিভঙ্গিকে দুর্নীতি থেকে রক্ষা করুন

আউটলুকে ত্রুটি এবং ডেটা নষ্ট হওয়ার ঝুঁকি থাকে, তাই আমাদের আউটলুক ডেটা সুরক্ষিত রাখা একটি অত্যন্ত কঠিন কাজ। নিঃসন্দেহে, সবচেয়ে কার্যকর এবং বাস্তবসম্মত উপায় হলো আউটলুকের জন্য নিয়মিত ডেটার ব্যাকআপ তৈরি করা। এর পাশাপাশি, আমাদের একটি শক্তিশালী এবং নির্ভরযোগ্য আউটলুক ফিক্স টুল সংগ্রহ করাও প্রয়োজন, যেমন— DataNumen Outlook Repair। এটা কাজে আসবে যদি ইনবক্স মেরামতের সরঞ্জাম কোন প্রভাব দেয়।

লেখকের ভূমিকা:

শিরলে জাং একটি ডেটা রিকভারি বিশেষজ্ঞ DataNumen, ইনক। যা তথ্য পুনরুদ্ধারের প্রযুক্তিগুলির সহ বিশ্বের শীর্ষস্থানীয় ঠিক করা SQL Server এবং আউটলুক মেরামত সফ্টওয়্যার পণ্য। আরো তথ্যের জন্য, যান WWW.datanumen.com

এখন শেয়ার:

মন্তব্যসমূহ বন্ধ করা হয়.