Как бързо да прикачите конкретните слайдове на a PowerPoint Презентация към вашия имейл в Outlook

Споделете сега:

Ако искате да извлечете конкретните слайдове на a PowerPoint презентация в отделна нова презентация и да я прикачите към имейл на Outlook, можете да използвате начина, споделен в тази статия.

Вместо да прикачите цяла PowerPoint презентация към имейл, ако искате да прикачите конкретните слайдове на презентацията, като цяло трябва първо да копирате конкретните слайдове в нова презентация. Това е твърде обезпокоително. Затова тук ще ви покажем метод, който може да го реализира наведнъж.

Бързо прикрепете конкретните слайдове на a PowerPoint Презентация към вашия имейл в Outlook

Прикачете конкретните слайдове на a PowerPoint Презентация към имейл

  1. Първо, отворете конкретното PowerPoint презентация.
  2. След това в PowerPoint прозорец на приложението, натиснете клавишите „Alt + F11“ за достъп до VBA редактор.
  3. След това в новия прозорец създайте нов модул, като натиснете „Вмъкване“ > „Модул“.
  4. Впоследствие копирайте и поставете следния VBA код в този модул.
Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

VBA код - прикрепете конкретните слайдове на a PowerPoint Презентация към имейл

  1. След това можете да затворите текущия прозорец.
  2. По-късно отидете на „Файл“ > „Опции“ > „Лента с инструменти за бърз достъп“, за да добавите новия макрос към лентата с инструменти за бърз достъп.
  3. И накрая, можете да опитате този макрос.
  • За начало изберете конкретните слайдове, които искате да извлечете.
  • След това щракнете върху бутона за макрос в лентата с инструменти за бърз достъп.Изпълнение на макрос върху избрани слайдове
  • Веднага ще се покаже имейл на Outlook, в който има a PowerPoint презентация, която е извлечена от изходната презентация.Извлечени презентационни слайдове

Използвайте ефективен инструмент за възстановяване

Както всички знаем, Outlook е надарен с вградена помощна програма за поправка – scanpst. И все пак той може просто да се справи с малки проблеми в Outlook. Ако това, с което се сблъсквате, е сериозна повреда, това няма да има ефект. В този момент нямате друг избор, освен да се върнете към друг мощен и надежден инструмент за ремонт, като например DataNumen Outlook Repair. С него ще можете да спасите вашия повреден файл в Outlook.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително повреден mdf и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com

Споделете сега:

Коментарите са забранени.