Как бързо да обедините и експортирате множество прикачени файлове на работната книга на Excel в една работна книга в Outlook

Когато получите имейл, прикачен с множество работни книги на Excel, ако искате да проверите съдържанието на всички работни книги в една работна книга, можете да използвате начина в тази статия. Той ще експортира множество прикачени файлове към работната книга на Excel в една работна книга.

За да видите всички прикачени файлове от работна книга на Excel към имейл в една работна книга на Excel, първо трябва да комбинирате и експортирате тези прикачени файлове в една работна книга. Вместо да правите това ръчно, можете да използвате следния метод, за да постигнете това с лекота. Той ще ви научи да използвате VBA код, за да го постигнете. Що се отнася до това как да използвате VBA, можете да се обърнете към публикацията „Как да стартирате VBA код във вашия Outlook".

Обединете и експортирайте множество прикачени файлове на работната книга на Excel в една работна книга

1. За начало стартирайте приложението си Outlook.
2. След това отворете редактора на Outlook VBA.
3. След това, в новия прозорец „Microsoft Visual Basic for Applications“, трябва да активирате „MS Excel Object Library“, за което можете да се обърнете към статията – „Как да добавите препратка към библиотека с обекти във VBA".
4. Впоследствие копирайте следния VBA код в проект или модул.

Sub CombineMultipleExcelWorkbookAttachmensIntoOne()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim strFile As String
    Dim objCurrentSheet As Excel.Worksheet
    Dim objCurrentBook As Excel.Workbook
    Dim objSheet As Excel.Worksheet
    Dim objFileSystem As Object
 
    On Error Resume Next
    'Create a new temp folder
    strTempFolder = "E:\Temp" & Format(Now, "yyymmddhhmmss") & "\"
    MkDir (strTempFolder)
 
    'Save selected attachments
    Set objSelectedAttachments = Outlook.Application.ActiveExplorer.AttachmentSelection
    For Each objAttachment In objSelectedAttachments
        objAttachment.SaveAsFile (strTempFolder & objAttachment.FileName)
    Next
 
    'Copy all the workbooks into a new file
    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelWorkbook.Activate
 
    strFile = Dir(strTempFolder)
    Do While strFile <> ""
       Set objCurrentBook = objExcelApp.Workbooks.Open(strTempFolder & strFile)
       For Each objCurrentSheet In objCurrentBook.Sheets
           objCurrentSheet.Copy Before:=objExcelWorkbook.Sheets(1)
       Next
 
       objExcelApp.Workbooks(strFile).Close
       strFile = Dir()
    Loop
 
    'Remove empty sheets
    objExcelApp.DisplayAlerts = False
    For Each objSheet In objExcelWorkbook.Worksheets
        If objExcelApp.WorksheetFunction.CountA(objSheet.Cells) = 0 Then
           objSheet.Delete
        End If
    Next
    objExcelApp.DisplayAlerts = True
 
    'Delete the temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. След това можете да затворите прозореца и да добавите новия макрос в лентата с инструменти за бърз достъп.
6. По-късно представете имейла на източника в пощенския списък.
7. След това задръжте „Ctrl“, за да изберете прикачените файлове на работната книга на Excel, които искате да експортирате.
8. След това щракнете върху бутона за макрос в лентата с инструменти за бърз достъп.
9. Когато макросът завърши, ще се покаже нова работна книга на Excel. Той ще съдържа съдържанието на предварително избраните работни книги на Excel.

Върнете се на по-мощен външен инструмент за ремонт

Когато се сблъскват с корупция в Outlook, повечето потребители са склонни да използват инструмент за ремонт на входящата кутия да опитате на първо място. Това обаче няма да е от голяма помощ в случай на сериозни щети. В този момент нямате друг избор, освен да се възползвате от външен надежден и опитен инструмент, като например DataNumen Outlook Repair.

Въведение на автора:

Шърли Джанг е експерт по възстановяване на данни в DataNumen, Inc., която е световен лидер в технологиите за възстановяване на данни, включително mdf възстановяване и outlook софтуерни продукти за ремонт. За повече информация посетете WWW.datanumen.com